_IEPropertyGet
Beschreibung anzeigen in
Gibt eine ausgewählte Eigenschaft des Browsers oder eines DOM Elementes zurück
#include <IE.au3>
_IEPropertyGet ( ByRef $oObject, $sProperty )
Parameter
| $oObject | Objektvariable einer InternetExplorer.Application oder eines DOM-Elementes |
| $sProperty | siehe Bemerkungen (Browsereigenschaften) |
Rückgabewert
| Erfolg: | die ausgewählte Eigenschaft |
| Fehler: | 0 und setzt das @error Flag auf ungleich null |
| @error: | 3 ($_IEStatus_InvalidDataType) - Ungültiger Datentyp 4 ($_IEStatus_InvalidObjectType) - Ungültiger Objekttyp 5 ($_IEStatus_InvalidValue) - Ungültiger Wert |
| @extended: | Nummer des ungültigen Parameters |
Bemerkungen
Die folgende Tabelle liefert eine Beschreibung der Eigenschaften, die möglich sind.
Einige sind Eigenschaften von DOM Elementen, andere des Browsers.
Browsereigenschaften
| Eigenschaften | Beschreibung |
| "adressbar" | Gibt einen Boolean-Wert zurück, ob die Adressleiste sichtbar ist oder nicht. |
| "browserx" | Gibt die X-Koordinate der oberen linken Ecke eines Dokumentenelements relativ zum Browser zurück. |
| "browsery" | Gibt die Y-Koordinate der oberen linken Ecke eines Dokumentenelements relativ zum Browser zurück. |
| "busy" | Gibt einen Boolean-Wert zurück, der angibt, ob das Objekt mit einer Navigations- oder Downloadoperation beschäftigt ist. |
| "contenteditable" | Gibt einen Boolean-Wert zurück, der angibt, ob das Objekt mit Maus und Tastatur editiert werden kann. |
| "fullscreen" | Gibt einen Boolean-Wert zurück, der angibt, ob der Browser im Vollbildmodus ist. |
| "height" | Gibt die Höhe des Haupt-Browserfensters oder eines Dokumentenelements zurück. |
| "hwnd" | Gibt das Handle des Internet Explorer-Hauptfensters zurück. Kann in den meisten AutoIt Win* Funktionen genutzt werden. |
| "innerhtml" | Gibt den erzeugten HTML-Code eines Elements ohne die anführenden und schließenden Markierungen zurück. |
| "innertext" | Gibt den erzeugten Text (ohne Markierungen) eines Elements zurück. (identisch mit "outertext") |
| "isdisabled" | Gibt einen Wert zurück, der angibt, ob der Benutzer das Objekt verändern kann. |
| "left" | Gibt die Bildschirmkoordinaten der linken Kante des Hauptfensters zurück, in dem sich das Objekt befindet. |
| "locationname" | Gibt den Namen der Seite zurück, die der Internet Explorer gerade darstellt. |
| "locationurl" | Gibt die URL (Internetadresse) der Seite zurück, die der Internet Explorer gerade darstellt. |
| "menubar" | Gibt einen Boolean-Wert zurück, ob die Browserleiste sichtbar ist. |
| "offline" | Gibt einen Boolean-Wert zurück, ob der Browser gerade offline ist. |
| "outertext" | Gibt den erzeugten Text (ohne Markierungen) eines Elements zurück. (identisch mit "innertext") |
| "outerhtml" | Gibt den erzeugten Text einschließlich der Markierungen eines Elements zurück. |
| "readystate" | Gibt den Status der Verfügbarkeit eines Objekts zurück.. |
| "referrer" | Gibt einen String mit der URL (Internetadresse) zurück, von der aus die aktuelle Seite aufgerufen wurde (aber nur, wenn die aktuelle Seite über einen Link der vorhergehenden Seite erreicht wurde, andernfalls ist der String Null). |
| "resizable" | Gibt einen Wert zurück, der angibt, ob ein Objekt in der Größe verändert werden kann. |
| "silent" | Gibt einen Wert zurück, der angibt, ob der Browser Dialogfenster anzeigen kann. |
| "statusbar" | Gibt einen Wert zurück, der angibt, ob die Statusbar eines Objektes sichtbar ist. |
| "statustext" | Gibt den Text der Statusbar für das Objekt zurück. |
| "theatermode" | Gibt einen Boolean-Wert zurück, ob der Browser im Theatermodus ist. Im Theatermodus füllt das Haupt-Browserfenster den gesamten Desktop aus und zeigt eine Symbolleiste mit einer eingeschränkten Anzahl an Navigationselementen an. |
| "title" | Gibt den Titel des Dokuments zurück. Beachte, dass dieser Titel nicht dem Fenstertitel entspricht, der zwar normalerweise mit dem Dokumententitel beginnt, der aber ergänzenden Text (z.B. aus der Registrierung) beinhalten kann. |
| "toolbar" | Gibt einen Boolean-Wert zurück, ob die Toolbar sichtbar ist. |
| "top" | Gibt die Bildschirmkoordinaten der oberen Kante des Hauptfensters zurück, in dem sich das Objekt befindet. |
| "visible" | Gibt einen Wert zurück, der angibt, ob das Objekt sichtbar oder unsichtbar ist. |
| "width" | Gibt die Breite des Browserfensters oder eines Objekts zurück. |
| "uniqueid" | Ermittelt die ID des Elements, welche vom DOM zugewiesen wurde, die einmalig unter allen Elementen ist. Diese kann in jedem Zusammenhang verwendet werden, der eine Element-ID benötigt. |
Weitere Informationen gibt es bei MSDN.
Client-Info Eigenschaften
| Eigenschaften | Beschreibung |
| "appcodename" | Gibt den Codenamen des Browsers zurück (die Eigenschaft hat den Standardwert Mozilla). |
| "appminorversion" | Gibt die Version der Anwendung in Kurzform zurück. |
| "appname" | Gibt den Namen des Browsers zurück (die Eigenschaft hat den Standardwert Microsoft Internet Explorer). |
| "appversion" | Gibt die Plattform und Version des Browsers zurück. |
| "browserlanguage" | Gibt die aktuelle Browsersprache zurück (der Wert entspricht einem dieser Sprachcodes). |
| "cookieenabled" | Gibt einen Wert zurück, der angibt, ob Client-seitige dauerhafte Cookies im Browser aktiviert sind. Dauerhafte Cookies sind solche, die auf dem lokalen Computer gespeichert werden. |
| "cpuclass" | Gibt einen String mit der Bezeichnung der CPU-Klasse zurück (die möglichen Rückgabewerte stehen hier). |
| "javaenabled" | Gibt einen Wert zurück, der angibt ob Java aktiviert ist. |
| "online" | Gibt einen Wert zurück, der angibt ob das System im ft.com/en-us/library/ie/aa768170(v=vs.85).aspx" target="_blank">Globalen Offline Modus ist. |
| "platform" | Gibt den Namen des Betriebsystems des Benutzers zurück (die möglichen Rückgabewerte stehen hier). |
| "systemlanguage" | Gibt die Standardsprache zurück, die vom Betriebssystem verwendet wird. Ermittelt die Standarsprache die vom Beitrebssystem verwendet wird (der Wert ist einer dieser Sprachcodes). |
| "useragent" | Gibt einen String zurück, der dem 'HTTP user-agent request header' entspricht. |
| "userlanguage" | Gibt die vom Benutzer eingestellte Sprache des Betriebssystems zurück. Der Wert entspricht einem dieser Sprachcodes). |
Verwandte Funktionen
_IEBodyReadHTML, _IEBodyReadText, _IEBodyWriteHTML, _IEDocInsertHTML, _IEDocInsertText, _IEHeadInsertEventScript, _IEPropertySet
Beispiel
Beispiel 1
#include <IE.au3>
#include <MsgBoxConstants.au3>
; Öffnet eine Browser-Instanz mit dem Grundbeispiel, prüft ob die Adressleiste sichtbar ist. Falls sie sichtbar ist wird sie versteckt und umgekehrt.
Local $oIE = _IE_Example("basic")
If _IEPropertyGet($oIE, "addressbar") Then
MsgBox($MB_SYSTEMMODAL, "Adressleiste Status", "Adressleiste sichtbar, verstecken der Adressleiste")
_IEPropertySet($oIE, "addressbar", False)
Else
MsgBox($MB_SYSTEMMODAL, "Adressleiste Status", "Adressleiste versteckt, einblenden der Adressleiste")
_IEPropertySet($oIE, "addressbar", True)
EndIf
Beispiel 2
;Öffnet eine Browser-Instanz mit dem Formularbeispiel und erhält einen Bezug zum Formularelement "Text".
;Erhält die Koordinaten und die Abmaße vom Textbereich, umfährt seine Kontur mit der Maus und bewegt sich zum Schluß in die Mitte des Formularelements
#include <IE.au3>
Local $oIE = _IE_Example("form")
Local $oForm = _IEFormGetObjByName($oIE, "ExampleForm")
Local $oTextArea = _IEFormElementGetObjByName($oForm, "textareaExample")
; Erhält die Koordinaten und Abmaße vom Textbereich
Local $iScreenX = _IEPropertyGet($oTextArea, "screenx")
Local $iScreenY = _IEPropertyGet($oTextArea, "screeny")
Local $iWidth = _IEPropertyGet($oTextArea, "width")
Local $iHeight = _IEPropertyGet($oTextArea, "height")
; Umfährt seine Kontur mit der Maus und bewegt sich zum Schluß in die Mitte des Formularelements
Local $iMousespeed = 50
MouseMove($iScreenX, $iScreenY, $iMousespeed)
MouseMove($iScreenX + $iWidth, $iScreenY, $iMousespeed)
MouseMove($iScreenX + $iWidth, $iScreenY + $iHeight, $iMousespeed)
MouseMove($iScreenX, $iScreenY + $iHeight, $iMousespeed)
MouseMove($iScreenX, $iScreenY, $iMousespeed)
MouseMove($iScreenX + $iWidth / 2, $iScreenY + $iHeight / 2, $iMousespeed)