ControlSetText
Beschreibung anzeigen in
Schreibt einen neuen Text in ein Control.
ControlSetText ( "title", "text", controlID, "new text" [, flag = 0] )
Parameter
| title | Der Titel des Fensters, auf das zugegriffen werden soll. Siehe spezielle Titeldefinition. |
| text | Der Text des Fensters, auf das zugegriffen werden soll. Siehe spezielle Textdefinition. |
| ControlID | Die ID des Controls, das beeinflusst werden soll. Siehe Controls. |
| new text | Der neue Text, der in das Control geschrieben werden soll. |
| flag | [optional] ist dieser Wert ungleich 0, dann wird veranlasst, dass das Zielfenster neu erstellt wird. |
Rückgabewert
| Erfolg: | Gibt 1 zurück. |
| Fehler: | Gibt 0 zurück wenn das Fenster bzw. Control nicht gefunden wurde. |
Verwandte Funktionen
ControlCommand, ControlGetText, ControlSend, SplashTextOn
Beispiel
#include <MsgBoxConstants.au3>
Example()
Func Example()
; Startet den Editor
Run("notepad.exe")
; Wartet maximal 10 Sekunden bis das Editorfenster erscheint.
Local $hWnd = WinWait("[CLASS:Notepad]", "", 10)
; Schreibt in das Edit-Control des Editors Text. Dabei wird für den "title" Parameter von ControlSetText das von WinWait zurückgegebenen Handle verwendet.
ControlSetText($hWnd, "", "Edit1", "This is some text")
; Ermittelt den Text im Edit-Control des Editors. Dabei wird für den "title" Parameter von ControlGetText das von WinWait zurückgegebenen Handle verwendet.
Local $sText = ControlGetText($hWnd, "", "Edit1")
; Zeigt den Text des Edit-Controls.
MsgBox($MB_SYSTEMMODAL, "", "Der Test in Edit1 lautet: " & $sText)
; Schließt das Editorfenster durch die Verwendung des von WinWait zurückgegebenen Handles.
WinClose($hWnd)
EndFunc ;==>Example