Funktionreferenz


SplashTextOn

Beschreibung anzeigen in

Erzeugt ein einstellbares Text-Anzeigefenster (PopUp).

SplashTextOn ( "title", "text" [, w = 500 [, h = 400 [, x pos [, y pos [, opt = 0 [, "fontname" [, fontsz = 12 [, fontwt]]]]]]]] )

Parameter

title Titel des Splash Fensters.
text Text des Splash Fensters.
w [optional] Breite des Fensters in Pixel (Standard 500).
h [optional] Höhe des Fensters in Pixel (Standard 400).
x pos [optional] Position von Links (in Pixel - Standard ist zentriert).
y pos [optional] Position von Oben (in Pixel - Standard ist zentriert).
opt [optional] Addierbare Optionen - Standard ist 'Zentriert ausgerichtet / immer im Vordergrund / mit Titel'
    $DLG_CENTERONTOP (0) = Zentriert ausgerichtet / immer im Vordergrund / mit Titel (Standard)
    $DLG_NOTITLE (1) = Dünne Aussenlinien, titelloses Fenster.
    $DLG_NOTONTOP (2) = Ohne "immer im Vordergrund" Attribut.
    $DLG_TEXTLEFT (4) = Linksbündiger Text
    $DLG_TEXTRIGHT (8) = Rechtsbündiger Text
    $DLG_MOVEABLE (16) = Fenster kann bewegt werden
    $DLG_TEXTVCENTER (32) = Text wird vertikal zentriert

Die Konstanten sind in AutoItConstants.au3 definiert.
fontname [optional] Schriftname. (Wenn für fontname "" gewählt wird oder der Schrifttyp nicht gefunden wurde, wird die im OS definierte GUI Standard-Schrift genommen.)
fontsz [optional] Schriftgröße. (Standard ist 12; Standard Größen sind 6 8 9 10 11 12 14 16 18 20 22 24 26 28 36 48 72)
fontwt [optional] Schriftdicke im Bereich von 0 bis 1000. Z.B.: 400 ist 'normal' und 700 ist 'bold'. Ist der Wert 0 dann wird ein Standardwert benutzt.
Der Einfachheit sind folgende Werte definiert:
    $FW_DONTCARE (0) (Standard Schriftdicke wird verwendet)
    $FW_THIN (100)
    $FW_EXTRALIGHT (200)
    $FW_LIGHT (300)
    $FW_NORMAL (400)
    $FW_MEDIUM (500)
    $FW_SEMIBOLD (600)
    $FW_BOLD (700)
    $FW_EXTRABOLD (800)
    $FW_HEAVY (900)

Die Konstanten sind in FontConstants.au3 definiert.

Rückgabewert

Gibt das Handle des Splash-Fensters zurück, welches für ControlSetText() verwendet werden kann.

Bemerkungen

Um einen optionalen Parameter zu überspringen, (also den Standardwert beizubehalten), benutzt man:
    "" für Text-Parameter.
    -1 für Zahl-Parameter.

Nur ein SplashImage/Text Fenster ist zur selben Zeit erlaubt. Sollen verschiedene Image/Text Fenster durchgegangen werden, ist SplashImageOn()/SplashTextOn() wiederholt mit den neuen Informationen aufzurufen.

Besser ist es, die Funktion ControlSetText() zu benutzen, um Text ohne Flackern zu aktualisieren...
Wenn der Text zentriert ist und sich in mehreren Zeilen befindet, dann wird ControlSetText() die Anzahl der Zeilen, welche durch SplashTextOn() erstellt wurden, nicht überschreiben.

Fenster mit opt=1 können nicht bewegt bzw. durch Anklicken aktiviert werden.

Enthaltene Standard-Schriftarten:
    Arial, Comic Sans MS, Courier New, Lucida Console, Microsoft Sans Serif, System, Tahoma, Times New Roman und WingDings
Siehe Appendix für eine komplette Schriftartenliste und unter welcher Windows Version sie unterstützt werden.

Um mehrere Zeilen darzustellen, ist @LF zu benutzen.

Damit innerhalb des Textes ein &-Zeichen angezeigt, muss an dieser Stelle zwei &-Zeichen hintereinander stehen.
Beispiel: Um 'Text&Text' anzuzeigen, muss man 'Text&&Text' schreiben.

Verwandte Funktionen

ControlSetText, MsgBox, SplashImageOn, SplashOff, ToolTip

Beispiel

#include <AutoItConstants.au3>

SplashTextOn("Titel", "Nachricht hier rein.", -1, -1, -1, -1, $DLG_TEXTLEFT, "", 24)
Sleep(3000)
SplashOff()

;; FLIMMERT
Local $sMessage = ""
SplashTextOn("Titelleiste", $sMessage, -1, -1, -1, -1, $DLG_TEXTLEFT, "")
For $x = 1 To 20
    $sMessage = $sMessage & $x & @CRLF
    SplashTextOn("Titelleiste", $sMessage, -1, -1, -1, -1, $DLG_TEXTLEFT, "")
    Sleep(100)
Next

;; FLIMMERT NICHT
$sMessage = ""
SplashTextOn("Titelleiste", $sMessage, -1, -1, -1, -1, $DLG_TEXTLEFT, "")
For $x = 1 To 20
    $sMessage = $sMessage & $x & @CRLF
    ControlSetText("Titelleiste", "", "Static1", $sMessage)
    Sleep(100)
Next