Ermittelt die Details zu einer Verknüpfung.
FileGetShortcut ( "lnk" )
lnk | Vollständiger Pfad und Dateiname der Verknüpfung. |
Erfolg: | Ein Array mit den Verknüpfungsdetails - siehe Bemerkungen. |
Fehler: | Setzt @error auf 1, wenn die Verknüpfung nicht geöffnet werden konnte. |
Das von dieser Funktion zurückgegebene Array ist ein ein-dimensionales Array, das folgende Elemente beinhaltet:
$aArray[0] = Verknüpfungsziel
$aArray[1] = Arbeitsverzeichnis
$aArray[2] = Argumente
$aArray[3] = Beschreibung
$aArray[4] = Dateiname des Icons
$aArray[5] = Index des Icons
$aArray[6] = Der Verknüpfungsstatus (@SW_SHOWNORMAL, @SW_SHOWMINNOACTIVE, @SW_SHOWMAXIMIZED)
#include <MsgBoxConstants.au3>
Example()
Func Example()
; Erstellt eine Konstante im lokalen Bereich des Dateipfads der Verknüpfung.
Local Const $sFilePath = @DesktopDir & "\FileGetShortcutExample.lnk"
; Erstellt eine Verknüpfung zur explorer.exe auf dem Desktop. Dabei wird der Tastenkombination Ctrl+Alt+T oder in AutoIt ^!t gesetzt.
FileCreateShortcut(@WindowsDir & "\explorer.exe", $sFilePath, @WindowsDir, "/e,c:\", _
"Tooltip Bescbreibung der Verknüpfung", @SystemDir & "\shell32.dll", "^!t", "15", @SW_SHOWMINNOACTIVE)
; Ermittelt Details zu der Verknüpfung.
Local $aDetails = FileGetShortcut($sFilePath)
If Not @error Then
MsgBox($MB_SYSTEMMODAL, "", "Pfad: " & $aDetails[0] & @CRLF & _
"Arbeitsverzeichnis: " & $aDetails[1] & @CRLF & _
"Argumente: " & $aDetails[2] & @CRLF & _
"Bescbreibung: " & $aDetails[3] & @CRLF & _
"Dateiname des Icons: " & $aDetails[4] & @CRLF & _
"Index des Icons: " & $aDetails[5] & @CRLF & _
"Verknüpfungsstatus: " & $aDetails[6] & @CRLF)
EndIf
; Löscht die Verknüpfung.
FileDelete($sFilePath)
EndFunc ;==>Example