IsFunc

Beschreibung anzeigen in

Prüft, ob eine Variable oder ein Ausdruck ein Funktionstyp ist.

IsFunc ( expression )

Parameter

expression

Die Variable oder der Ausdruck die/der geprüft werden soll.

Rückgabewert

Erfolg:	1 falls die Variable eine benutzerdefinierte Funktion ist, 2 falls die Variable eine native Funktion ist.
Fehler:	0 falls der Ausdruck kein Funktionstyp ist.

Bemerkungen

Siehe Sprach-Datentypen für eine detaillierte Beschreibung.

Beispiel

Beispiel 1


#include <MsgBoxConstants.au3>

Beispiel()

Func Beispiel()
    ; Erstellt ein Objekt erster Klasse von MsgBox und weist es einer lokalen Variablen zu.
    Local $hMsgBox = MsgBox

    ; Zeigt eine MsgBox unter Verwendung der zuvor zugewiesenen Variablen.
    $hMsgBox($MB_SYSTEMMODAL, "", "Dies ist ein Satz mit Whitespace.")

    ; Prüft, ob $hMsgBox eine Funktion ist und zeigt das Ergebnis in einer MsgBox an.
    $hMsgBox($MB_SYSTEMMODAL, "", "Prüft, ob $hMsgBox eine Funktion ist oder nicht." & @CRLF & _
            @CRLF & _
            "Es wird der Wert 2 zurückgegeben, da die Funktion nativ ist: " & IsFunc($hMsgBox))
EndFunc   ;==>Beispiel

Beispiel 2


#include <MsgBoxConstants.au3>

Beispiel()

Func Beispiel()
    ; Erstellt ein Objekt erster Klasse von MsgBox und weist es einer lokalen Variablen zu.
    Local $hMsgBox = MsgBox

    ; Zeigt eine MsgBox unter Verwendung der zuvor zugewiesenen Variablen an.
    $hMsgBox($MB_SYSTEMMODAL, "", "Dies ist ein Satz mit Whitespace.")

    ; Weist die Variable $hMsgBox mit unserer benutzerdefinierten Messagebox-Funktion neu zu.
    $hMsgBox = MeineMsgBox

    ; Prüft, ob $hMsgBox eine Funktion ist und zeigt das Ergebnis in einer MsgBox an.
    $hMsgBox($MB_SYSTEMMODAL, "", "Prüft, ob $hMsgBox eine Funktion ist oder nicht." & @CRLF & _
            @CRLF & _
            "Es wird der Wert 1 zurückgegeben, da die Funktion eine Benutzerfunktion ist: " & IsFunc($hMsgBox))
EndFunc   ;==>Beispiel

; Benutzerdefinierte MsgBox-Funktion.
Func MeineMsgBox($iFlag, $sTitle, $sText = "")
    Return MsgBox($iFlag, $sTitle, $sText)
EndFunc   ;==>MeineMsgBox

Funktionreferenz