Funktionreferenz

StringCompare

Beschreibung anzeigen in

Vergleicht zwei Strings mit Optionen.

StringCompare ( "string1", "string2" [, casesense = 0] )

Parameter

string1 Der erste auszuwertende String.
string2 Der zweite auszuwertende String.
casesense [optional] Flag zur Suchgenauigkeit.
    $STR_NOCASESENSE (0) = Groß- und Kleinschreibung werden nicht berücksichtigt (Standardwert).
    $STR_CASESENSE (1) = Berücksichtigt Groß- und Kleinschreibung.
    $STR_NOCASESENSEBASIC (2) = Groß- und Kleinschreibung werden nicht berücksichtigt. Es findet ein einfacherer schnellerer Vergleich statt.

Die Konstanten sind in StringConstants.au3 definiert

Rückgabewert

0: string1 und string2 sind gleich
> 0: string1 ist größer als string2
< 0: string1 ist kleiner als string2

Verwandte Funktionen

StringInStr, StringLeft, StringLen, StringLower, StringMid, StringRight, StringTrimLeft, StringTrimRight, StringUpper

Beispiel

#include <MsgBoxConstants.au3>
#include <StringConstants.au3>

Local $sStr1 = "Tiësto"
Local $sStr2 = "TIËSTO"

; Vergleicht zwei String ohne die Groß- und Kleinschreibung.
Local $iCmp = StringCompare($sStr1, $sStr2)
MsgBox($MB_SYSTEMMODAL, "", _
        "Vergleiche '" & $sStr1 & "' mit '" & $sStr2 & "'" & @CRLF & _
        "StringCompare Ergebnis (Modus $STR_NOCASESENSE): " & $iCmp)

; Vergleicht zwei String unter Berücksichtigung der Groß- und Kleinschreibung.
$iCmp = StringCompare($sStr1, $sStr2, $Str_CASESENSE)
MsgBox($MB_SYSTEMMODAL, "", _
        "Vergleiche '" & $sStr1 & "' mit '" & $sStr2 & "'" & @CRLF & _
        "StringCompare Ergebnis (Modus $STR_CASESENSE): " & $iCmp)

; Vergleicht zwei String ohne die Groß- und Kleinschreibung.
$iCmp = StringCompare($sStr1, $sStr2, $Str_NOCASESENSEBASIC)
MsgBox($MB_SYSTEMMODAL, "", _
        "Vergleiche '" & $sStr1 & "' mit '" & $sStr2 & "'" & @CRLF & _
        "StringCompare Ergebnis (Modus $STR_NOCASESENSEBASIC): " & $iCmp)