WinList

Beschreibung anzeigen in

Ruft eine Liste von Fenstern ab.

WinList ( ["title" [, "text"]] )

Parameter

title	[optional] Der Titel/hWnd/Klasse des/der Fenster, die gelesen werden sollen. Siehe Erweiterte Fenstertiteldefinition.
text	[optional] Der Text des/der Fenster, die gelesen werden sollen. Der Standardwert ist eine leere Zeichenfolge. Siehe Erweiterte Fenstertextdefinition.

Rückgabewert

Gibt ein Array mit den Fenstertiteln und den entsprechenden Handles zurück.

Bemerkungen

Wird kein Titel und Text angegeben werden alle top-level Fenster zurückgegeben.

Das zurückgegebene Array ist 2-dimensional und wie folgt aufgebaut:
    $aArray[0][0] = Anzahl der gefundenen Fenster.
    $aArray[1][0] = erster Fenstertitel.
    $aArray[1][1] = erste Fenster-ID (Handle=HWND)
    $aArray[2][0] = zweiter Fenstertitel
    $aArray[2][1] = zweite Fenster-ID (Handle=HWND)
    ...
    $aArray[n][0] = n-ter Fenstertitel
    $aArray[n][1] = n-te Fenster-ID (Handle=HWND)

Beispiel

Beispiel 1

#include <MsgBoxConstants.au3>

Example()

Func Example()
    ; Ermittelt eine Liste mit Fensterhandles.
    Local $aList = WinList()

    ; Durchläuft das Array und zeigt nur die Titel der sichtbaren Fenster.
    For $i = 1 To $aList[0][0]
        If $aList[$i][0] <> "" And BitAND(WinGetState($aList[$i][1]), 2) Then
            MsgBox($MB_SYSTEMMODAL, "", "Titel: " & $aList[$i][0] & @CRLF & "Handle: " & $aList[$i][1])
        EndIf
    Next
EndFunc   ;==>Example

Beispiel 2

#include <Array.au3>

Example()

Func Example()
    ; Ermittelt eine Liste mit Fensterhandles durch die Verwendung eines regulären Ausdrucks. Der reguläre Ausdruck prüft den Titel der die Wörter 'SciTE' oder 'Internet Explorer' enthält.
    Local $aWinList = WinList("[REGEXPTITLE:(?i)(.*SciTE.*|.*Internet Explorer.*)]")
    _ArrayDisplay($aWinList)
EndFunc   ;==>Example

Funktionreferenz