Funktionreferenz

_Array2DCreate

Beschreibung anzeigen in

Erstellt ein 2D-Array aus zwei 1D oder 2D-Arrays

#include <Array.au3>
_Array2DCreate ( $aArray1, $aArray2 )

Parameter

$aArray1 Ein 1D oder 2D-Array
$aArray2 Ein 1D oder 2D-Array

Rückgabewert

Erfolg: Ein 2D Array.
Fehler: Setzt das @error Flag.
@error: 1 wenn einer der beiden Parameter nicht ein 1D oder 2D-Array ist.
2 die 1D oder 2D-Arrays sind nicht gleich groß.
3 wenn einer der Parameter kein Array ist.

Bemerkungen

Die Funktion ist gültig für 1D + 1D, 1D + 2D, 2D + 1D oder 2D + 2D (Siehe Beispiel #2)

Beispiel

Beispiel 1

#include <Array.au3>

Local $oDi = ObjCreate('scripting.dictionary')
For $i = 0 To 10
    $oDi.Add('key' & $i, 'item' & $i)
Next

_ArrayDisplay(_Array2DCreate($oDi.Keys, $oDi.Items))

Beispiel 2 _Array2DCreate() mit 1D oder 2D Arrays

#include <Array.au3>

Local $aArray3

Local $aArray1 = [10, 11, 12]
Local $aArray2 = [20, 21, 22]
$aArray3 = _Array2DCreate($aArray1, $aArray2)
If @error Then Exit MsgBox(0, "_Array2DCreate 1D + 1D", "Fehler " & @error)
_ArrayDisplay($aArray3, "1D + 1D")

Local $aArray1 = [10, 11, 12]
Local $aArray2 = [[20, 23], [21, 24], [22, 25]]
$aArray3 = _Array2DCreate($aArray1, $aArray2)
If @error Then Exit MsgBox(0, "_Array2DCreate 1D + 2D", "Fehler " & @error)
_ArrayDisplay($aArray3, "1D + 2D")

Local $aArray1 = [[10, 13], [11, 14], [12, 15]]
Local $aArray2 = [20, 21, 22]
$aArray3 = _Array2DCreate($aArray1, $aArray2)
If @error Then Exit MsgBox(0, "_Array2DCreate 2D + 1D", "Fehler " & @error)
_ArrayDisplay($aArray3, "2D + 1D")
Local $aArray1 = [[10, 13], [11, 14], [12, 15]]
Local $aArray2 = [[20, 23], [21, 24], [22, 25]]
$aArray3 = _Array2DCreate($aArray1, $aArray2)
If @error Then Exit MsgBox(0, "_Array2DCreate 2D + 2D", "Fehler " & @error)
_ArrayDisplay($aArray3, "2D + 2D")

Local $oDi = ObjCreate('scripting.dictionary')
For $i = 0 To 10
    $oDi.Add('key' & $i, 'item' & $i)
Next

$aArray3 = _Array2DCreate($oDi.Keys, $oDi.Items)
If @error Then Exit MsgBox(0, "_Array2DCreate Objekt 1D + 1D", "Fehler " & @error)
_ArrayDisplay($aArray3, "Objekt 1D + 1D", "", 0, Default, Default, -90)