Funktionreferenz


_IEFormGetCollection

Beschreibung anzeigen in

Gibt eine Auflistung von Objektvariablen zurück, die alle Formulare (HTML-Tag) in dem Dokument oder ein einzelnes Formular (über seinen Index charakterisiert) beinhaltet

#include <IE.au3>
_IEFormGetCollection ( ByRef $oObject [, $iIndex = -1] )

Parameter

$oObject Objektvariable einer InternetExplorer.Application, eines Window-, eines Frame- oder eines iFrame-Objekts.
$iIndex [optional] Legt fest, ob eine Auflistung aller Formulare in dem Dokument oder eines einzelnen Formulars.
 0 oder ein positiver Integer, welcher die indizierten Instanzen enthält
-1 = (Standard) Gibt eine Sammlung zurück.

Rückgabewert

Erfolg: eine Objektvariable mit einer Sammlung aller Formulare in dem Dokument, @extended = Anzahl der Formulare
Fehler: Setzt das @error Flag auf ungleich null
@error: 3 ($_IEStatus_InvalidDataType) - Ungültiger Dateityp
5 ($_IEStatus_InvalidValue) - Ungültiger Wert
7 ($_IEStatus_NoMatch) - Keine Übereinstimmung
@extended: Nummer des ungültigen Parameters

Verwandte Funktionen

_IEFormGetObjByName, _IEFormReset, _IEFormSubmit

Beispiel

Beispiel 1

#include <IE.au3>

; Stellt einen Verweis auf eine spezifische Form vom 0-basierenden Index her;
; In diesem Fall die erste Form auf der Seite

Local $oIE = _IECreate("http://www.google.com")
Local $oForm = _IEFormGetCollection($oIE, 0)
Local $oQuery = _IEFormElementGetCollection($oForm, 4)
_IEFormElementSetValue($oQuery, "AutoIt IE.au3")
_IEFormSubmit($oForm)

Beispiel 2

#include <IE.au3>
#include <MsgBoxConstants.au3>

; Stellt einen Verweis auf die Sammlung von Formen auf einer Seite her
; Und zeigt dann, in einer Schleife, alle Informationen für jede Form an

Local $oIE = _IECreate("http://www.autoitscript.com")
Local $oForms = _IEFormGetCollection($oIE)
MsgBox($MB_SYSTEMMODAL, "Formen Informationen", "Es befinden sich " & @extended & " Formen auf dieser Seite")
For $oForm In $oForms
    MsgBox($MB_SYSTEMMODAL, "Form Information", $oForm.name)
Next

Beispiel 3

#include <IE.au3>
#include <MsgBoxConstants.au3>

; Stellt einen Verweis auf die Sammlung von Formen auf einer Seite her
; Und zeigt dann, in einer Schleife, alle Informationen für jede Anzeige-Nutzung vom Form-Index an


Local $oIE = _IECreate("http://www.autoitscript.com")
Local $oForms = _IEFormGetCollection($oIE)
Local $iNumForms = @extended
MsgBox($MB_SYSTEMMODAL, "Formen Informationen", "Es befinden sich " & $iNumForms & " Formen auf dieser Seite")
Local $oForm
For $i = 0 To $iNumForms - 1
    $oForm = _IEFormGetCollection($oIE, $i)
    MsgBox($MB_SYSTEMMODAL, "Form Information", $oForm.name)
Next