_Word_DocFindReplace

Beschreibung anzeigen in

Führt die angegebene "suchen und ersetzen" Funktion aus

#include <Word.au3>
_Word_DocFindReplace ( $oDoc [, $sFindText = "" [, $sReplaceWith = "" [, $iReplace = $WdReplaceAll [, $vSearchRange = 0 [, $bMatchCase = False [, $bMatchWholeWord = False [, $bMatchWildcards = False [, $bMatchSoundsLike = False [, $bMatchAllWordForms = False [, $bForward = True [, $iWrap = $WdFindContinue [, $bFormat = False]]]]]]]]]]]] )

Parameter

$oDoc	Word Document Objekt
$sFindText	[optional] Der Text nach dem gesucht werden soll. "" gibt an, dass nur nach Formatierung gesucht werden soll. Es kann nach Steuerzeichen gesucht werden, indem der entsprechende Zeichencode angegeben wird. Beispiel: "^p" entspricht einem Paragraphenzeichen, "^t" einem Tabulatorzeichen (Standard = "")
$sReplaceWith	[optional] Der ersetzende Text. "" löscht den gefundenen Text. Steuerzeichen und erweiterte Suchkriterien werden wie bei _Word_DocFind() verwendet (Standard = "")
$iReplace	[optional] Gibt an, wie oft der Suchtext ersetzt werden soll (ein Mal, all, kein Mal). Kann eine Konstante der WdReplace Aufzählung sein (Standard = $WdReplaceAll)
$vSearchRange	[optional] Definiert die Markierung (Selection) oder den Bereich (Range) der durchsucht werden soll. Mögliche Werte: -1 - Durchsucht die aktive Markierung 0 - Durchsucht das ganze Dokument document (Standard) Ein beliebiger Bereich (Range) des Dokumentes
$bMatchCase	[optional] Bei True wird Groß-/Kleinschreibung bei der Suche beachtet (Standard = False)
$bMatchWholeWord	[optional] Bei True wird nur nach ganzen Worten gesucht (Standard = False)
$bMatchWildcards	[[optional] Bei True enthält der Suchtext spezielle Suchoperatoren (Standard = False)
$bMatchSoundsLike	[optional] Bei True werden Worte, die dem Suchtext ähnlich klingen gefunden (Standard = False)
$bMatchAllWordForms	[optional] Bei True werden alle Abwandlungen des Suchtextes gefunden (e.g. "sitzen" findet "sitzen" und "saß") (Standard = False)
$bForward	[optional] Bei True wird zusätzlich zum oder anstatt des Suchtextes nach Textformatierung gesucht (Standard = False)
$iWrap	[optional] Bei True wird, wenn der Anfang oder das Ende des Dokumentes, der Markierung oder des Bereiches erreicht wird, am anderen Ende weitergesucht. Kann eine Konstante der WdFindWrap Aufzählung sein (Standard = $WdFindContinue)
$bFormat	[optional] Bei True wird zusätzlich zum oder anstatt des Suchtextes nach Textformatierung gesucht (Standard = False)

Rückgabewert

Erfolg:	1.
Fehler:	0 und sets @error ungleich 0.
@error:	1 - $oDoc ist kein Objekt 2 - $vSearchRange ist kein Objekt 3 - Ein Fehler trat beim Ersetzen des Textes auf. @extended wird auf den COM Fehlercode gesetzt

Beispiel

Beispiel 1

#include <MsgBoxConstants.au3>
#include <Word.au3>

; Erzeugt ein neues oder stellt eine Verbindung zu einem bestehenden Word-Objekt her
Local $oWord = _Word_Create()
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocFindReplace Beispiel 1", _
        "Fehler beim Erstellen des Word-Anwendungsobjektes." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
; Öffnet das Testdokument im Lesemodus
Local $oDoc = _Word_DocOpen($oWord, @ScriptDir & "\Extras\Test.doc", Default, Default, True)
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocFindReplace Beispiel 1", _
        "Fehler beim Öffnen von '.\Extras\Test.doc'." & @CRLF & "@error = " & @error & ", @extended = " & @extended)

; Ändert den Text "test document" in "test document with replaced text".
_Word_DocFindReplace($oDoc, "test document", "test document with replaced text")
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocFindReplace Beispiel 1", _
        "Fehler beim Ersetzen des Textes." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocFindReplace Beispiel 1", "Text erfolgreich ersetzt.")

Beispiel 2

#include <MsgBoxConstants.au3>
#include <Word.au3>

; Erzeugt ein neues oder stellt eine Verbindung zu einem bestehenden Word-Objekt her
Local $oWord = _Word_Create()
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocFindReplace Beispiel 2", _
        "Fehler beim Erstellen des Word-Anwendungsobjektes." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
; Öffnet das Testdokument im Lesemodus
Local $oDoc = _Word_DocOpen($oWord, @ScriptDir & "\Extras\Test.doc", Default, Default, True)
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocFindReplace Beispiel 2", _
        "Fehler beim Öffnen von '.\Extras\Test.doc'." & @CRLF & "@error = " & @error & ", @extended = " & @extended)

; Ersetzt das Paragraf-Steuerzeichen durch Paragraf-Steuerzeichen + Text + Paragraf-Steuerzeichen.
; Ersetzt nur das erste Auftreten.
_Word_DocFindReplace($oDoc, "^p", "^pInserted Line^p", $wdReplaceOne)
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocFindReplace Beispiel 2", _
        "Fehler beim Ersetzen des Textes." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocFindReplace Beispiel 2", "Das Paragraf-Steuerzeichen wurde erfolgreich ersetzt.")