_Word_DocPictureAdd
Beschreibung anzeigen in
Fügt ein Bild in das DOkument ein
#include <Word.au3>
_Word_DocPictureAdd ( $oDoc, $sFilePath [, $bLinkToFile = False [, $bSaveWithDocument = False [, $oRange = 0]]] )
Parameter
| $oDoc | Word Dokument Objekt |
| $sFilePath | Der Pfad und Dateiname des Bildes |
| $bLinkToFile | [optional] Gibt an, ob das Bild mit der Datei, aus der es erstellt wurde, verknüpft werden soll. True - Verknüpfe das Bild mit der Datei, aus der es erstellt wurde False - Das ingefügte Bild ist eine unabhängige Kopie der Datei (Standard) |
| $bSaveWithDocument | [optional] Gibt an, ob das verknüpfte Bild mit dem Dokument gesichert werden soll. True - Speichere das verknüpfte Bild mit dem Dokument False - Speichere das verknüpfte Bild nicht mit dem Dokument (Standard) |
| $oRange | [optional] Die Position wo das Bild im Text platziert werden soll. Kann entweder 0 (das Bild wird automatisch platziert) oder ein Bereichs-Objekt (Range) sein (Standard = 0) |
Rückgabewert
| Erfolg: | Objekt des eingefügten Bildes (Shape) |
| Fehler: | 0 und setzt das @error Flag auf ungleich null. |
| @error: | 1 - $oDoc ist kein Objekt 2 - Die angegebene Datei konnte nicht gefunden werden 3 - Ein Fehler trat beim Einfügen der angegebenen Datei auf. @extended wird auf den COM Fehlercode gesetzt 4 - $oRange ist nicht 0 aber auch kein Bereichs-Objekt (Range) |
Beispiel
Beispiel 1
#include <MsgBoxConstants.au3>
#include <Word.au3>
; Erzeugt ein neues oder stellt eine Verbindung zu einem bestehenden Word-Objekt her
Local $oWord = _Word_Create()
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocPictureAdd Beispiel 1", _
"Fehler beim Erstellen des Word-Anwendungsobjektes." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
; Öffnet das Testdokument
Local $oDoc = _Word_DocOpen($oWord, @ScriptDir & "\Extras\Test.doc", Default, Default, True)
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocPictureAdd Beispiel 1", _
"Fehler beim Öffnen von '.\Extras\Test.doc'." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
; Fügt nach dem vierten Wort im Dokument eine Bilddatei ein.
; Setzt das Range Objekt als Einfügemarke nach dem vierten Wort.
Local $oRange = _Word_DocRangeSet($oDoc, -1, Default, 4, Default, 4)
_Word_DocPictureAdd($oDoc, @ScriptDir & "\Extras\Screenshot.png", Default, Default, $oRange)
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocPictureAdd Beispiel 1", _
"Fehler beim Einfügen der Bilddatei" & @CRLF & " @error = " & @error & ", @extended = " & @extended)
MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocPictureAdd Beispiel 1", _
"Bilddatei wurde erfolgreich nach dem vierten Wort in das Dokument eingefügt.")
Beispiel 2
#include <MsgBoxConstants.au3>
#include <Word.au3>
; Erzeugt ein neues oder stellt eine Verbindung zu einem bestehenden Word-Objekt her
Local $oWord = _Word_Create()
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocPictureAdd Beispiel 2", _
"Fehler beim Erstellen des Word-Anwendungsobjektes." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
; Öffnet das Testdokument
Local $oDoc = _Word_DocOpen($oWord, @ScriptDir & "\Extras\Test.doc", Default, Default, True)
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocPictureAdd Beispiel 2", _
"Fehler beim Öffnen von '.\Extras\Test.doc'." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
; Fügt am Ende des Dokumentes eine Bilddatei ein.
; Setzt das Range Objekt als Einfügemarke auf das Dokumentenende..
Local $oRange = _Word_DocRangeSet($oDoc, -2)
_Word_DocPictureAdd($oDoc, @ScriptDir & "\Extras\Screenshot.png", Default, Default, $oRange)
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocPictureAdd Beispiel 2", _
"Fehler beim Einfügen der Bilddatei." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocPictureAdd Beispiel 2", _
"Bilddatei wurde erfolgreich am Ende des Dokumentes eingefügt.")