_Word_DocTableWrite
Beschreibung anzeigen in
Schreibt einen ein- oder zwei-dimensionalen Array in eine Word Tabelle
#include <Word.au3>
_Word_DocTableWrite ( $oRange, ByRef $aArray [, $iIndexBase = Default [, $sDelimiter = Default]] )
Parameter
| $oRange | Word Bereichs-Objekt wo die Tabelle eingefügt werden soll |
| $aArray | ein- oder zwei-dimensionaler Array der in die Word Tabelle umgewandelt werden soll. Der Array kann bei Zeile 0 oder 1 beginnen |
| $iIndexBase | [optional] Kann 0 oder 1 sein und definiert, ob der Array mit Zeile 0 oder 1 beginnt (Standard = 1) |
| $sDelimiter | [optional] Das Zeichen, das verwendet wird um Text in Zellen aufzuteilen. Eine Konstante der WdTableFieldSeparator Aufzählung (Standard = @TAB) |
Rückgabewert
| Erfolg: | Das Word Tabellen Objekt. |
| Fehler: | 0 und setzt das @error Flag auf ungleich null. |
| @error: | 1 - $oRange ist kein Objekt 2 - $aArray ist kein Array oder hat mehr als 2 Dimensionen 3 - Fehler beim Zugriff auf das Bereichs-Objekt (Range). @extended wird auf den COM Fehlercode gesetzt 4 - Fehler beim Konvertieren des Arrays in eine Tabelle. @extended wird auf den COM Fehlercode gesetzt |
Bemerkungen
Der Array darf kein @CR, @CRLF oder @LF in einer Zelle enthalten.
Wenn der Array @TAB enthält, dann muss der Parameter $sDelimiter auf ein anderes Zeichen gesetzt werden.
Verwandte Funktionen
Beispiel
#include <MsgBoxConstants.au3>
#include <Word.au3>
; Erzeugt ein neues oder stellt eine Verbindung zu einem bestehenden Word-Objekt her
Local $oWord = _Word_Create()
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocTableWrite Beispiel", _
"Fehler beim Erstellen des Word-Anwendungsobjektes." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
; Öffnet das Testdokument
Local $oDoc = _Word_DocOpen($oWord, @ScriptDir & "\Extras\Test.doc", Default, Default, True)
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocTableWrite Beispiel", _
"Fehler beim Öffnen von '.\Extras\Test.doc'." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
; Schreibt den Inhalt eines 0-basierten Arrays in eine Word Tabelle
Local $asArray[3][3] = [[1, 2, 3], ["a", "b", "c"], ["x", "y", "z"]]
Local $oRange = _Word_DocRangeSet($oDoc, -2)
_Word_DocTableWrite($oRange, $asArray, 0)
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocTableWrite Beispiel", _
"Fehler beim Erstellen der Tabelle." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocTableWrite Beispiel", _
"Tabelle erfolgreich am Ende des Dokumentes eingefügt.")