Ändert den Titel des AutoIt-Fensters.
AutoItWinSetTitle ( "newtitle" )
newtitle | Der neue Titel, der dem Fenster zugeteilt werden soll. |
Das AutoItfenster ist normalerweise versteckt. Der Zweck des Änderns des AutoItfenster liegt darin, anderen Programmen (oder anderen AutoItscripts) zu ermöglichen mit AutoIt zu "kommunizieren".
AutoItWinGetTitle, WinSetTitle
; Es ist zu prüfen, ob das Skript bereits läuft
; Es wird empfohlen dazu _Singleton von der Misc.au3 zu verwenden
#include <MsgBoxConstants.au3>
Local $sMyAutoItTitle = "ThisIsSomeUniqueStringThatOtherWindowsWontHave"
If WinExists($sMyAutoItTitle) Then
; Das Skript läuft bereits
MsgBox($MB_SYSTEMMODAL, Default, "Das Skript läuft bereits." & @CRLF & @CRLF & _
"Die PID lautet: " & WinGetProcess($sMyAutoItTitle))
Else
; Dies ist die erste Instanz des Skripts.
; Setzt denFenstertitel von AutoIt
AutoItWinSetTitle($sMyAutoItTitle)
; Startet das Skript erneut.
If @Compiled Then
Run('"' & @ScriptFullPath & '"')
Else
Run('"' & @AutoItExe & '" "' & @ScriptFullPath & '"')
EndIf
MsgBox($MB_SYSTEMMODAL, Default, "Dies ist die erste Instanz." & @CRLF & @CRLF & _
"Meinbe PID lautet: " & @AutoItPID)
EndIf
#include <GUIConstantsEx.au3>
Example()
Func Example()
; Setzt den Titel des versteckten AutoIt Fensters
AutoItWinSetTitle("Mein AutoIt Fenster")
; Zeigt das versteckte AutoIt Fenster.
AutoItWinShow()
While 1
Switch GUIGetMsg()
Case $GUI_EVENT_CLOSE
ExitLoop
EndSwitch
WEnd
EndFunc ;==>Example
; Zeigt das versteckte AutoIt Fenster. Gibt das Handle des Fensters zurück.
Func AutoItWinShow()
Local $hWnd = WinGetHandle(AutoItWinGetTitle()) ; Ermittelt das Handle des versteckten AutoIt Fensters durch das ermitteln des Titels des versteckten AutoIt Fensters.
WinMove($hWnd, "", (@DesktopWidth / 2) - 250, (@DesktopHeight / 2) - 250, 500, 500) ; Verschiebt das versteckte AutoIt Fenster und ändert die Größe für eine bessere Ansicht.
WinSetState($hWnd, "", @SW_SHOW) ; Zeigt das versteckte AutoIt Fenster. Normalerweise ist dieses versteckt, aber in diesem Beispiel wird des gezeigt.
Return $hWnd
EndFunc ;==>AutoItWinShow