Ruft eine Funktion in einer DLL dynamisch auf.

DllCall ( "dll", "return type", "function" [, type1, param1 [, type n, param n]] )

Parameter

Rückgabewert

Bemerkungen

Wenn der Dateiname einer DLL angegeben wird, wird die DLL automatisch geladen und nach den Funktionsaufruf wieder geschlossen. Wenn man das Laden und Entladen selbst kontrollieren will, verwendet man dazu die Funktionen DllOpen() und DllClose() und gibt statt des Dateinamens ein Handle an.

Normalerweise benutzt AutoIt die 'stdcall'-Befehlsmethode. Um die 'cdecl'-Methode zu benutzen ist ':cdecl' nach dem Rückgabewert "return type" zu setzen:
DllCall("SQLite.dll", "int:cdecl", "sqlite3_open", "str", $sDatabase_Filename , "long_*", 0).

Standardmäßig versucht AutoIt, die ANSI-Variante des Funktionsnamens zu verwenden, d.h. MessageBoxA wird verwendet, wenn MessageBox als Funktionsname gegeben ist. Um explizit die Unicode-Variante aufzurufen, kann MessageBoxW verwendet werden.

Wenn der Funktionsaufruf scheitert, wird @error auf ungleich 0 gesetzt.
Ansonsten wird ein Array mit dem Rückgabewert der Funktion und einer Kopie aller Parameter (inklusive derer, die die Funktion möglicherweise verändert hat) zurückgegeben.
$return[0] = Rückgabewert der Funktion
$return[1] = Param1
$return[2] = Param2
...
$return[n] = Paramn

Wenn ein Ausgabeparameter vom Typ STR oder WSTR als Null-String definiert ist, wird nur ein Maximum von 65536 Strings zurückgegeben.

Es können beliebig viele "type"- und "param"-Parameter angegeben werden. Siehe die Beispiele unten, die viele Parameter verwenden.

Verwandte Funktionen

DllCallbackFree, DllCallbackGetPtr, DllCallbackRegister, DllClose, DllOpen, DllStructCreate, DllStructGetPtr

Beispiel

Beispiel 1

; Direkter Aufruf der Nachrichtenfenster-API.
DllCall("user32.dll", "int", "MessageBox", _
        "hwnd", 0, _ ; Handle des Hauptfensters
        "str", "Some text", _ ; Der Text des Nachrichtenfensters
        "str", "Some title", _ ; Der Titel des Nachrichtenfensters
        "int", 0) ; Flags des Nachrichtenfensters

Beispiel 2

#include <MsgBoxConstants.au3>

;Aufrufen einer Funktion, die Parameter verändert
Local $iPID = Run("notepad")

Local $hWnd = WinWait("[CLASS:Notepad]", "", 2000)

If $hWnd = 0 Then
    ; Wartezeit abgelaufen.
    Exit MsgBox($MB_SYSTEMMODAL, Default, "Es ist nicht möglich den Editor zu starten!")
EndIf

Local $aResult = DllCall("user32.dll", "int", "GetWindowText", "hwnd", $hWnd, "str", "", "int", 32768)
MsgBox($MB_SYSTEMMODAL, Default, "Anzahl zurückgegebener Zeichen: " & $aResult[0])
MsgBox($MB_SYSTEMMODAL, Default, "Text (zurückgegeben in Parameter 2): '" & $aResult[2] & "'")

WinClose($hWnd)

Beispiel 3

#include <MsgBoxConstants.au3>

;Den Windows PickIconDlg anzeigen
Local $sFileName = @SystemDir & '\shell32.dll'

; Struktur erzeugen um den Iconindex abzuspeichern
Local $tIconIndex = DllStructCreate("int")
Local $tString = DllStructCreate("wchar[260]")
Local $iStructsize = DllStructGetSize($tString) / 2
DllStructSetData($tString, 1, $sFileName)

; Den PickIconDlg starten - '62' ist der Ordinalwert für diese Funktion
DllCall("shell32.dll", "none", 62, _
        "hwnd", 0, _
        "struct*", $tString, _
        "int", $iStructsize, _
        "struct*", $tIconIndex)

$sFileName = DllStructGetData($tString, 1)
Local $iIconIndex = DllStructGetData($tIconIndex, 1)

; Den neuen Dateinamen und den Iconindex anzeigen
MsgBox($MB_SYSTEMMODAL, "Info", "Die zuletzt ausgewählte Datei: " & $sFileName & @CRLF & "Icon-Index: " & $iIconIndex)