FileGetTime
Gibt die Zeit- und Datumsinformationen einer Datei zurück.
FileGetTime ( "filename" [, option = 0 [, format = 0]] )
Parameter
| filename | Der Pfad zur zu prüfenden Datei bzw. zum zu prüfenden Verzeichnis |
| option | [optional] Flag, das angibt, welche Zeit ausgelesen werden soll: $FT_MODIFIED (0) = Verändert (Standard) $FT_CREATED (1) = Erstellt $FT_ACCESSED (2) = Letzter Zugriff Die Konstanten sind in FileConstants.au3 definiert |
| format | [optional] Bestimmt die Rückgabeart: $FT_ARRAY (0) = Gibt ein Array zurück (Standard) $FT_STRING (1) = Gibt einen String im Format JJJJMMTTHHMMSS zurück $FT_MSEC (2) = Gibt Millisekunden zurück $FT_UTC (4) = Gibt die UTC Zeit anstatt der Ortszeit zurück Die Konstanten sind in FileConstants.au3 definiert |
Rückgabewert
| Erfolg: | Ein Array oder ein String, das/der die Zeit- und Datumsinformationen enthält - siehe Bemerkungen. |
| Fehler: | 0 und setzt das @error Flag auf ungleich 0. |
Bemerkungen
Das Array ist ein 1D Array, das sechs oder sieben Elemente enthält:
$aArray[0] = Jahr (vierstellig)
$aArray[1] = Monat (Bereich: 01 - 12)
$aArray[2] = Tag (Bereich: 01 - 31)
$aArray[3] = Stunden (Bereich: 00 - 23)
$aArray[4] = Minuten (Bereich: 00 - 59)
$aArray[5] = Sekunden (Bereich: 00 - 59)
Wenn „format“ $FT_MSEC und $FT_ARRAY enthält, erhält man
$aArray[6] = msec (Bereich 00–999)
Wenn "format" $FT_MSEC und $FT_STRING beinhaltet, gibt FileGetTime einen String YYYYMMDDHHMMSSnnn zurück
Es ist zu beachten, dass die Rückgabewerte bei Bedarf mit Nullen aufgefüllt sind.
Verwandte Funktionen
FileGetAttrib, FileGetSize, FileGetVersion, FileSetAttrib, FileSetTime
Beispiel
#include <FileConstants.au3>
#include <MsgBoxConstants.au3>
#include <WinAPIFiles.au3>
Example()
Func Example()
; Erstellt eine Konstante im lokalen Bereich des Dateipfads der gelesen bzw. geschrieben werden soll.
Local Const $sFilePath = _WinAPI_GetTempFileName(@TempDir)
; Setzt den modifizierten Zeitstempel der Datei auf den 1. November 2003 und die aktuelle Zeit.
Local $iFileSetTime = FileSetTime($sFilePath, "20031101", $FT_MODIFIED)
; Zeigt den modifizierten Zeitstempel der Datei und gibt diesen im Format YYYYMMDDHHMMSS zurück.
If $iFileSetTime Then
MsgBox($MB_SYSTEMMODAL, "", "Zeitstempel:" & @CRLF & FileGetTime($sFilePath, $FT_MODIFIED, $FT_STRING))
Else
MsgBox($MB_SYSTEMMODAL, "", "Es ist während dem setzen des Zeitstempels der Datei ein Fehler aufgetreten.")
EndIf
; Löscht die temporäre Datei.
FileDelete($sFilePath)
EndFunc ;==>Example