IniDelete
Beschreibung anzeigen in
Löscht einen Wert aus einer standardkonformen .ini-Datei.
IniDelete ( "filename", "section" [, "key"] )
Parameter
| filename | Der Dateiname der .ini-Datei. |
| section | Der Name der Sektion in der .ini-Datei. |
| key | [optional] Der Schlüssel, der gelöscht werden soll. Wenn nichts angegeben wird, wird die gesamte Sektion entfernt. Es kann auch das Schlüsselwort default verwendet werden, was ebenfalls zum Löschen der kompletten Sektion führt. |
Rückgabewert
| Erfolg: | 1. |
| Fehler: | 0, wenn die Sektion/der Schlüssel nicht gefunden wurde oder die Datei schreibgeschützt ist. |
Bemerkungen
Eine standardkonforme .ini-Datei sieht folgendermaßen aus:
[SektionsName]
Schlüssel=Wert
Verwandte Funktionen
IniRead, IniReadSection, IniReadSectionNames, IniRenameSection, IniWrite, IniWriteSection
Beispiel
#include <MsgBoxConstants.au3>
#include <WinAPIFiles.au3>
Example()
Func Example()
; Erstellt eine Konstante im lokalen Bereich des Dateipfades, welcher zum lesen bzw. schreiben verwendet wird.
Local Const $sFilePath = _WinAPI_GetTempFileName(@TempDir)
; Schreibt den Wert von 'AutoIt' in den Schlüssel 'Titel' und in die Sektion 'General'.
IniWrite($sFilePath, "General", "Titel", "AutoIt")
; Liest in der ini-Datei den Wert von 'Titel' in der Sektion 'General'.
Local $sRead = IniRead($sFilePath, "General", "Titel", "Default Value")
; Zeigt den Wert der von IniRead zurückgegeben wurde.
MsgBox($MB_SYSTEMMODAL, "", "Der Wert von 'Titel' in der Sektion 'General' lautet: " & $sRead)
; Löscht den Schlüssel 'Titel'
IniDelete($sFilePath, "General", "Titel")
; Liest in der ini-Datei den Wert von 'Titel' in der Sektion 'General'.
$sRead = IniRead($sFilePath, "General", "Titel", "Default Value")
; Zeigt den Wert der von IniRead zurückgegeben wurde. Falls es dort keinen Schlüssel gibt, wird der Standardwert übergeben von IniRead angezeigt.
MsgBox($MB_SYSTEMMODAL, "", "Der Wert von 'Titel' in der Sektion 'General' lautet: " & $sRead)
; Löscht die ini-Datei.
FileDelete($sFilePath)
EndFunc ;==>Example