Funktionreferenz

IniRead

Beschreibung anzeigen in

Liest einen Wert aus einer standardkonformen .ini-Datei.

IniRead ( "filename", "section", "key", "default" )

Parameter

filename Der Dateiname der .ini-Datei.
section Der Name der Sektion in der .ini-Datei.
key Der Name des Schlüssels in der .ini-Datei.
default Der Standardwert, der verwendet wird, wenn der gefragte Schlüssel nicht existiert.

Rückgabewert

Erfolg: den Wert des angefragten Schlüssels
Fehler: den default-String, wenn der angefragte Schlüssel nicht existiert.

Bemerkungen

Eine standardkonforme .ini-Datei sieht folgendermaßen aus:
[SektionsName]
Schlüssel=Wert

Alle Werte werden als String zurückgegeben.
Wenn der Wert ein anderer Datentyp sein muss, muss er mit der entsprechenden Funktion erzwungen werden: Int(), Number(), Ptr() oder HWnd().

Verwandte Funktionen

FileReadLine, IniDelete, IniReadSection, IniReadSectionNames, IniRenameSection, IniWrite, IniWriteSection

Beispiel

#include <MsgBoxConstants.au3>
#include <WinAPIFiles.au3>

Example()

Func Example()
    ; Erstellt eine Konstante im lokalen Bereich des Dateipfades, welcher zum lesen bzw. schreiben verwendet wird.
    Local Const $sFilePath = _WinAPI_GetTempFileName(@TempDir)

    ; Schreibt den Wert von 'AutoIt' in den Schlüssel 'Titel' und in die Sektion 'General'.
    IniWrite($sFilePath, "General", "Titel", "AutoIt")

    ; Liest in der ini-Datei den Wert von 'Titel' in der Sektion 'General'.
    Local $sRead = IniRead($sFilePath, "General", "Titel", "Default Value")

    ; Zeigt den Wert der von IniRead zurückgegeben wurde.
    MsgBox($MB_SYSTEMMODAL, "", "Der Wert von 'Titel' in der Sektion 'General' lautet: " & $sRead)

    ; Löscht den Schlüssel 'Titel'
    IniDelete($sFilePath, "General", "Titel")

    ; Liest in der ini-Datei den Wert von 'Titel' in der Sektion 'General'.
    $sRead = IniRead($sFilePath, "General", "Titel", "Default Value")

    ; Zeigt den Wert der von IniRead zurückgegeben wurde. Falls es dort keinen Schlüssel gibt, wird der Standardwert übergeben von IniRead angezeigt.
    MsgBox($MB_SYSTEMMODAL, "", "Der Wert von 'Titel' in der Sektion 'General' lautet: " & $sRead)

    ; Löscht die ini-Datei.
    FileDelete($sFilePath)
EndFunc   ;==>Example