Funktionreferenz

TraySetState

Beschreibung anzeigen in

Setzt den Status des Trayicons.

TraySetState ( [flag = 1] )

Parameter

flag [optional] Eine Kombination der folgenden Flags ist möglich:
    $TRAY_ICONSTATE_SHOW (1) = Zeigt das Trayicon (Standard)
    $TRAY_ICONSTATE_HIDE (2) = Löscht bzw. versteckt das Trayicon
    $TRAY_ICONSTATE_FLASH (4) = Lässt das Trayicon ausblinken
    $TRAY_ICONSTATE_STOPFLASH (8) = Stoppt das blinken des Trayicons
    $TRAY_ICONSTATE_RESET (16) = Setzt das Icon auf den Standard zurück (kein blinken, Standard Text)

Die Konstanten sind in TrayConstants.au3 definiert.

Rückgabewert

Keine.

Bemerkungen

Diese Funktion überschreibt Opt("TrayIconHide") und #NoTrayIcon.
Das normale und pausierende Icon wird durch diese Funktion NICHT zurückgesetzt!

Verwandte Funktionen

TrayItemSetState, TraySetIcon, TraySetPauseIcon

Beispiel

#include <MsgBoxConstants.au3>
#include <StringConstants.au3>
#include <TrayConstants.au3> ; wird für die $TRAY_ICONSTATE_SHOW Konstante benötigt.

#NoTrayIcon

Opt("TrayMenuMode", 3) ; Die Standard Traymenüeinträge (Skript pausieren/beenden) werden nicht angezeigt und die Items werden nicht angehakt wenn diese ausgewählt werden. Verwendet wurden die Optionen 1 und 2 für TrayMenuMode.

Example()

Func Example()
    Local $idFlash = TrayCreateItem("Flash Icon")
    TrayCreateItem("") ; Erzeugt einen Trennstrich.

    Local $idAbout = TrayCreateItem("About")
    TrayCreateItem("") ; Erzeugt einen Trennstrich.

    Local $idExit = TrayCreateItem("Exit")

    TraySetState($TRAY_ICONSTATE_SHOW) ; Zeigt das Traymenü.

    While 1
        Switch TrayGetMsg()
            Case $idAbout ; Zeigt ein Nachrichtenfenster mit der AutoIt Version und dem Installationspfad der AutoIt Startdatei.
                MsgBox($MB_SYSTEMMODAL, "", "AutoIt Traymenü Beispiel." & @CRLF & @CRLF & _
                        "Version: " & @AutoItVersion & @CRLF & _
                        "Installationspfad: " & StringLeft(@AutoItExe, StringInStr(@AutoItExe, "\", $STR_NOCASESENSEBASIC, -1) - 1)) ; Ermittelt den Ordner eines kompletten Pfads.

            Case $idFlash
                ; Beginnt mit dem blinken des Trayicons.
                TraySetState($TRAY_ICONSTATE_FLASH)
                Sleep(5000) ; Wartet 5 Sekunden.
                ; Beendet das blinken des Trayicons.
                TraySetState($TRAY_ICONSTATE_STOPFLASH)

            Case $idExit ; Beendet die Schleife.
                ExitLoop
        EndSwitch
    WEnd
EndFunc   ;==>Example