Funktionreferenz


_Date_Time_DOSDateTimeToArray

Beschreibung anzeigen in

Dekodiert ein DOS-Datum/Zeit in ein Array

#include <Date.au3>
_Date_Time_DOSDateTimeToArray ( $iDosDate, $iDosTime )

Parameter

$iDosDate MS-DOS Datum, verpackt wie folgt:
Bits 0- 4 Tag des Monats (1–31)
Bits 5- 8 Monat (1 = Januar, 2 = Februar und so weiter)
Bits 9-15 ausgehend vom Jahr 1980 (es ist 1980 hinzuzuaddieren, um das aktuelle Jahr zu bekommen)
$iDosTime MS-DOS Datum, verpackt wie folgt:
Bits 0- 4 Sekunde geteilt durch 2
Bits 5-10 Minute (0–59)
Bits 11-15 Stunde (0–23 im 24h-Format)

Rückgabewert

Gibt ein Array mit dem folgenden Format zurück:
    [0] - Monat
    [1] - Tag
    [2] - Jahr
    [3] - Stunde
    [4] - Minute
    [5] - Sekunde

Verwandte Funktionen

_Date_Time_DOSDateToArray, _Date_Time_DOSTimeToArray

Beispiel

#include <Date.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Global $g_idMemo

Example()

Func Example()
    Local $aDate

    ; Erstellt die GUI
    GUICreate("Zeit", 400, 300)
    $g_idMemo = GUICtrlCreateEdit("", 2, 2, 396, 296, $WS_VSCROLL)
    GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")
    GUISetState(@SW_SHOW)

    ; Zeigt FAT Datum/Uhrzeit
    $aDate = _Date_Time_DOSDateTimeToArray(0x3621, 0x944a) ; 01/01/2007 18:34:20
    MemoWrite("FAT Datum  :" & StringFormat("%02d.%02d.%04d", $aDate[1], $aDate[0], $aDate[2]))
    MemoWrite("FAT Uhrzeit:" & StringFormat("%02d:%02d:%02d", $aDate[3], $aDate[4], $aDate[5]))

    ; Die Schleife wiederholt sich, bis der Benutzer die Beenden-Aktion der GUI auslöst.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example

; Funktion schreibt eine Zeile in das iMemo-Control
Func MemoWrite($sMessage)
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite