Funktionreferenz

_Date_Time_GetSystemTimeAsFileTime

Beschreibung anzeigen in

Gibt das aktuelle Systemdatum und die Systemzeit im UTC-Format zurück

#include <Date.au3>
_Date_Time_GetSystemTimeAsFileTime ( )

Rückgabewert

Gibt die $tagFILETIME Struktur zurück die das aktuelle Systemdatum und die Systemzeit beinhaltet

Verwandte Funktionen

$tagFILETIME

Beispiel

#include <Date.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Global $g_idMemo

Example()

Func Example()
    Local $tTime

    ; Erstellt eine GUI
    GUICreate("Zeit", 400, 300)
    $g_idMemo = GUICtrlCreateEdit("", 2, 2, 396, 296, $WS_VSCROLL)
    GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")
    GUISetState(@SW_SHOW)

    ; Ermittelt die Systemzeit
    $tTime = _Date_Time_GetSystemTimeAsFileTime()

    MemoWrite("Systemzeit: " & _Date_Time_FileTimeToStr($tTime))

    ; Die Schleife wiederholt sich, bis der Benutzer eine Beenden-Aktion auslöst
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example

; Gibt eine Zeile im Memo-Fenster aus
Func MemoWrite($sMessage)
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite