Funktionreferenz

_Date_Time_GetTimeZoneInformation

Beschreibung anzeigen in

Ermittelt die aktuellen Zeitzonen Einstellungen

#include <Date.au3>
_Date_Time_GetTimeZoneInformation ( )

Rückgabewert

Erfolg: Array mit dem folgenden Format:
    [0] - Sommerzeit Einstellungen. Kann einen der folgenden Werte annehmen:
        -1 - Fehler
         0 - Sommerzeit wird in der aktuellen Zeitzonen Einstellung nicht verwendet
         1 - Sommerzeit arbeitet mit der Standardzeit
         2 - Sommerzeit arbeitet mit der Sommerzeit
    [1] - Der aktuelle Bias für die Umsetzung der lokalen Zeit. Der Bias ist die Differenz in Minuten zwischen der Universal Time Coordinated (UTC) und der lokalen Zeit. Alle Umsetzungen zwischen UTC und der lokalen Zeit verwenden die folgende Formel: UTC = lokale Zeit + Bias
    [2] - Die Beschreibung der Standardzeit
    [3] - Eine $tagSYSTEMTIME Struktur, die ein Datum und eine lokale Zeit beinhaltet, wenn eine Differenz zwischen lokaler und Sommerzeit entsteht.
    [4] - Der Bias Wert, der verwendet wird, während Anpassungen an die lokale Zeit während der Standardzeit vorgenommen werden. Dieser Wert wird zum Wert des Bias addiert um diesen während der Standardzeit zu verwenden. In den meisten Zeitzonen ist dieser Wert 0.
    [5] - Die Beschreibung der Sommerzeit
    [6] - Eine $tagSYSTEMTIME Struktur, die ein Datum und eine lokale Zeit beinhaltet, wenn die Änderung von Standardzeit zu Sommerzeit erfolgt.
    [7] - Der Bias Wert der verwendet wird, während der Änderung von lokaler Zeit zu Sommerzeit. Dieser Wert wird zu dem Bias Wert addiert, der während der Sommerzeit verwendet wird. In den meisten Fällen ist dieser Wert -60.
Fehler: Setzt das @error Flag auf ungleich null.

Bemerkungen

In der $tagSYSTEMTIME Struktur stellt wHour und wMinute die Zeitänderung, wDayOfWeek den zugehörigen Wochentag und wDay die Anzahl der Tage innerhalb des Monats. (1 bis 5, wobei 5 das letzte Auftreten während des Monats darstellt falls dieser Wochentag wengier als 5 Mal auftritt).

Anmerkung:
Um 02:00 auf den ersten Sonntag im April festzulegen sind folgende Werte notwendig: wHour = 2, wMonth = 4, wDayOfWeek = 0, wDay = 1.
Um 02:00 auf den letzten Donnerstag im Oktober festzulegen sind folgende Werte notwendig: wHour = 2, wMonth = 10, wDayOfWeek = 4, wDay = 5.

Verwandte Funktionen

$tagSYSTEMTIME, _Date_Time_SetTimeZoneInformation

Beispiel

;~ #RequireAdmin
; Die Windows API "SetTimeZoneInformation" benötigt "SeTimeZonePrivilege", so dass #RequireAdmin verwendet werden muss

#include <Date.au3>
#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>
#include <WinAPIError.au3>
#include <WindowsConstants.au3>

Global $g_idMemo

Example()

Func Example()
    ; Erstellt eine GUI
    GUICreate("Datum Zeit: Setzt und ermittelt die Zoneninformationen (v" & @AutoItVersion & ")", 460, 460)
    $g_idMemo = GUICtrlCreateEdit("", 2, 2, 456, 456, $WS_VSCROLL)
    GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")
    GUISetState(@SW_SHOW)

    ; Zeigt Infos über die aktuelle Zeitzone
    Local $aOld = _Date_Time_GetTimeZoneInformation()
    ShowTimeZoneInformation($aOld, "Current")

    ; Setzt die neue Zeitzone. Nur Namenupdates
    If Not _Date_Time_SetTimeZoneInformation($aOld[1], "A3L CST", $aOld[3], $aOld[4], "A3L CDT", $aOld[6], $aOld[7]) Then
        MsgBox($MB_SYSTEMMODAL, "Fehler", "Die Systemzeit kann nicht gesetzt werden" & @CRLF & @CRLF & _WinAPI_GetErrorMessage(@extended))
        Exit
    EndIf

    ; Zeigt Infos über die neue Zeitzone
    Local $aNew = _Date_Time_GetTimeZoneInformation()
    ShowTimeZoneInformation($aNew, "New")

    ; Setzt auf originale Zeitzone zurück
    _Date_Time_SetTimeZoneInformation($aOld[1], $aOld[2], $aOld[3], $aOld[4], $aOld[5], $aOld[6], $aOld[7])

    ; Zeigt Infos über die aktuelle Zeitzone
    $aOld = _Date_Time_GetTimeZoneInformation()
    ShowTimeZoneInformation($aOld, "Reset")

    ; Die Schleife wiederholt sich, bis der Benutzer die Beenden-Aktion der GUI auslöst.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example

; Gibt eine Zeile im Memo-Fenster aus
Func MemoWrite($sMessage)
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite

; Zeigt Details der Zeitzone an
Func ShowTimeZoneInformation(ByRef $aInfo, $sComment)
    MemoWrite("******************* " & $sComment & " *******************")
    MemoWrite("Ergebnis ...................: " & $aInfo[0])
    MemoWrite("Aktuelle Verschiebung ......: " & $aInfo[1])
    MemoWrite("Standardname ...............: " & $aInfo[2])
    MemoWrite("Standard Datum/Zeit ........: " & _Date_Time_SystemTimeToDateTimeStr($aInfo[3]))
    MemoWrite("Standard Verschiebung ......: " & $aInfo[4])
    MemoWrite("Sommerzeit Name ............: " & $aInfo[5])
    MemoWrite("Sommerzeit Datum/Zeit ......: " & _Date_Time_SystemTimeToDateTimeStr($aInfo[6]))
    MemoWrite("Sommerzeitverschiebung .....: " & $aInfo[7])
EndFunc   ;==>ShowTimeZoneInformation