_Excel_RangeReplace

Beschreibung anzeigen in

Findet und ersetzt übereinstimmenden Text in einem Bereich oder einem Arbeitsblatt

#include <Excel.au3>
_Excel_RangeReplace ( $oWorkbook, $vWorksheet, $vRange, $sSearch, $sReplace [, $iLookAt = $xlPart [, $bMatchcase = False]] )

Parameter

$oWorkbook	Excel Arbeitsbuch-Objekt
$vWorksheet	Name, Index oder Arbeitsblatt-Objekt das durchsucht werden soll. Wird das Schlüsselwort Default gesetzt, so wird das aktive Arbeitsblatt genutzt
$vRange	Ein Bereichs-Objekt, ein A1 Bereich oder das Schlüsselwort Default um alle Zellen im angegebenen Arbeitsblatt zu durchsuchen
$sSearch	Der zu suchende Text
$sReplace	Der ersetzende Text
$iLookAt	[optional] Gibt an, ob der Suchtext vollständig zutreffen muss, oder nur ein Teil. Kann eine Konstante aus der XLLookAt Aufzählung sein (Standard = $xlPart)
$bMatchcase	[optional] True = Groß- und Kleinschreibung wird berücksichtigt, False = Groß- und Kleinschreibung wird ignoriert (Standard = False)

Rückgabewert

Erfolg:	Das Bereichs-Objekt und setzt @extended auf 1, wenn mindestens eine Zelle geändert wurde.
Fehler:	0 und setzt @error.
@error:	1 - $oWorkbook ist kein Objekt oder kein Arbeitsbuch-Objekt 2 - $vWorksheet Name oder Index ist falsch oder $vWorksheet ist kein Arbeitsblatt-Objekt. @extended ist auf den COM Fehlercode gesetzt 3 - $sSearch ist leer 4 - $vRange ist ungültig. @extended ist auf den COM Fehlercode gesetzt 5 - Fehler von der Replace-Methode zurückgegeben. @extended ist auf den COM Fehlercode gesetzt

Beispiel

Beispiel 1

#include <Excel.au3>
#include <MsgBoxConstants.au3>

; Anwendungsobjekt erstellen und eine Beispielarbeitsmappe öffnen
Local $oExcel = _Excel_Open()
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Excel UDF: _Excel_RangeReplace Example", "Fehler beim Erstellen des Excel-Anwendungsobjekts." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
Local $oWorkbook = _Excel_BookOpen($oExcel, @ScriptDir & "\Extras\_Excel1.xls")
If @error Then
    MsgBox($MB_SYSTEMMODAL, "Excel UDF: _Excel_RangeReplace Example", "Fehler beim Öffnen der Arbeitsmappe '" & @ScriptDir & "\Extras\_Excel1.xls'." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
    _Excel_Close($oExcel)
    Exit
EndIf

; Inhalt der Zelle A1 durch einen anderen Wert ersetzen
MsgBox($MB_SYSTEMMODAL, "Excel UDF: _Excel_RangeReplace Example 1", "OK drücken, um die Daten in Zelle 'A1' zu ändern..")
_Excel_RangeReplace($oWorkbook, Default, "A1", 1, 3.37)
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Excel UDF: _Excel_RangeReplace Example 1", "Fehler beim Ersetzen von Daten im Bereich." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
MsgBox($MB_SYSTEMMODAL, "Excel UDF: _Excel_RangeReplace Example 1", "Daten in Zelle 'A1' erfolgreich ersetzt.")

Beispiel 2

#include <Excel.au3>
#include <MsgBoxConstants.au3>

; Anwendungsobjekt erstellen und eine Beispielarbeitsmappe öffnen
Local $oExcel = _Excel_Open()
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Excel UDF: _Excel_RangeReplace Example", "Fehler beim Erstellen des Excel-Anwendungsobjekts." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
Local $oWorkbook = _Excel_BookOpen($oExcel, @ScriptDir & "\Extras\_Excel1.xls")
If @error Then
    MsgBox($MB_SYSTEMMODAL, "Excel UDF: _Excel_RangeReplace Example", "Fehler beim Öffnen der Arbeitsmappe '" & @ScriptDir & "\Extras\_Excel1.xls'." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
    _Excel_Close($oExcel)
    Exit
EndIf

; Alle Zellen mit Text "long " finden und entfernen (durch "" ersetzen)
MsgBox($MB_SYSTEMMODAL, "Excel UDF: _Excel_RangeReplace Example 1", "OK drücken, um die Daten in der Zelle 'G1' zu ändern.")
_Excel_RangeReplace($oWorkbook, Default, Default, "long ", "")
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Excel UDF: _Excel_RangeReplace Example 2", "Fehler beim Ersetzen von Daten im Bereich." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
MsgBox($MB_SYSTEMMODAL, "Excel UDF: _Excel_RangeReplace Example 2", "Text 'long' entfernen." & @CRLF & "Daten erfolgreich ersetzt.")