_GDIPlus_DrawImagePoints
Beschreibung anzeigen in
Zeichnet ein Bild an einer festgelegten Stelle (Verzerrung möglich)
#include <GDIPlus.au3>
_GDIPlus_DrawImagePoints ( $hGraphic, $hImage, $nULX, $nULY, $nURX, $nURY, $nLLX, $nLLY [, $iCount = 3] )
Parameter
| $hGraphic | Handle zu einem Grafik-Objekt |
| $hImage | Handle zu einem Bild-Objekt |
| $nULX | Die X Koordinate der oberen linken Ecke des Quellbildes |
| $nULY | Die Y Koordinate der oberen linken Ecke des Quellbildes |
| $nURX | Die X Koordinate der oberen rechten Ecke des Quellbildes |
| $nURY | Die Y Koordinate der oberen rechten Ecke des Quellbildes |
| $nLLX | Die X Koordinate der unteren linken Ecke des Quellbildes |
| $nLLY | Die Y Koordinate der unteren linken Ecke des Quellbildes |
| $iCount | [optional] legt die Anzahl von Punkten (x,y) in der Struktur fest. |
Rückgabewert
| Erfolg: | True |
| Fehler: | False und setzt das @error Flag auf ungleich null, das @extended Flag kann den GPSTATUS-Fehlercode ($GPID_ERR* siehe GDIPlusConstants.au3) enthalten. |
Bemerkungen
Der Wert des count Parameters muss exakt 3 sein, um die Koordinaten der oberen linken Ecke, der oberen rechten Ecke und der unteren linken Ecke des Parallelogramms festzulegen.
Die Koordinaten der unteren rechten Ecke, die Breite und die Höhe des Bildes werden durch die drei gegebenen Koordinaten berechnet.
Das Bild wird skaliert, damit es in das Parallelogramm passt.
Siehe auch
Suche nach GdipDrawImagePoints in der MSDN Bibliothek.
Beispiel
#include <GDIPlus.au3>
#include <ScreenCapture.au3>
#include <WinAPIHObj.au3>
Example()
Func Example()
Local $hBitmap1, $hBitmap2, $hImage1, $hImage2, $hGraphic
; Initialisiert (startet) Microsoft Windows GDI+
_GDIPlus_Startup()
; Erstellt vom kompletten Bildschirm einen Screenshot
$hBitmap1 = _ScreenCapture_Capture("")
$hImage1 = _GDIPlus_BitmapCreateFromHBITMAP($hBitmap1)
; Erstellt von einem Bereich einen Screenshot
$hBitmap2 = _ScreenCapture_Capture("", 0, 0, 400, 300)
$hImage2 = _GDIPlus_BitmapCreateFromHBITMAP($hBitmap2)
; Zeichnet ein Bild in ein anderes
$hGraphic = _GDIPlus_ImageGetGraphicsContext($hImage1)
_GDIPlus_DrawImagePoints($hGraphic, $hImage2, 100, 100, 600, 170, 130, 570)
; Zeichnet einen Rahmen um das eingefügte Bild
_GDIPlus_GraphicsDrawRect($hGraphic, 100, 100, 400, 300)
; Speichert das neue Bild
_GDIPlus_ImageSaveToFile($hImage1, @MyDocumentsDir & "\GDIPlus_Image.jpg")
; Ressourcen freigeben
_GDIPlus_ImageDispose($hImage1)
_GDIPlus_ImageDispose($hImage2)
_WinAPI_DeleteObject($hBitmap1)
_WinAPI_DeleteObject($hBitmap2)
; Gibt die durch Microsoft Windows GDI+ verwendeten Ressourcen wieder frei
_GDIPlus_Shutdown()
ShellExecute(@MyDocumentsDir & "\GDIPlus_Image.jpg")
EndFunc ;==>Example