Funktionreferenz

_GDIPlus_Shutdown

Beschreibung anzeigen in

Gibt die durch Microsoft Windows GDI+ verwendeten Ressourcen wieder frei

#include <GDIPlus.au3>
_GDIPlus_Shutdown ( )

Rückgabewert

Erfolg: True
Fehler: False und setzt das @error Flag auf ungleich null. @extended kann den GPSTATUS Fehlercode ($GPID_ERR* siehe GDIPlusConstants.au3) enthalten.

Bemerkungen

Es müssen alle GDI+ Objekte aufgelöst werden, bevor _GDIPlus_Shutdown() aufgerufen wird.

Verwandte Funktionen

_GDIPlus_Startup

Siehe auch

Suche nach GdiplusShutdown in der MSDN Bibliothek.

Beispiel

#include <GDIPlus.au3>
#include <GUIConstantsEx.au3>
#include <ScreenCapture.au3>
#include <WinAPIHObj.au3>

Example()

Func Example()
    Local $hGui, $hBMP, $hBitmap, $hGraphic

    ; Erstellt vom oberen, linken Bereich des Bildschirms einen Screenshot
    $hBMP = _ScreenCapture_Capture("", 0, 0, 400, 300)

    ; Erstellt eine GUI
    $hGui = GUICreate("GDI+", 400, 300)
    GUISetState(@SW_SHOW)

    ; Initialisiert (startet) Microsoft Windows GDI+
    _GDIPlus_Startup()

    ; Zeichnet ein Bitmap auf die GUI
    $hBitmap = _GDIPlus_BitmapCreateFromHBITMAP($hBMP)
    $hGraphic = _GDIPlus_GraphicsCreateFromHWND($hGui)
    _GDIPlus_GraphicsDrawImage($hGraphic, $hBitmap, 0, 0)

    ; Ressourcen freigeben
    _GDIPlus_GraphicsDispose($hGraphic)
    _GDIPlus_ImageDispose($hBitmap)
    _WinAPI_DeleteObject($hBMP)

    ; Gibt die durch Microsoft Windows GDI+ verwendeten Ressourcen wieder frei
    _GDIPlus_Shutdown()

    ; Die Schleife wiederholt sich, bis der Benutzer die Beenden-Aktion der GUI auslöst.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example