Funktionreferenz


_GDIPlus_GraphicsClear

Beschreibung anzeigen in

Färbt ein Grafik-Objekt in einer festgelegten Farbe

#include <GDIPlus.au3>
_GDIPlus_GraphicsClear ( $hGraphics [, $iARGB = 0xFF000000] )

Parameter

$hGraphics Handle zu einem Grafik-Objekt
$iARGB [optional] Alpha, Rot, Grün und Blau Komponenten der Farbe

Rückgabewert

Erfolg: True
Fehler: False und setzt das @error Flag auf ungleich null, das @extended Flag kann den GPSTATUS-Fehlercode ($GPID_ERR* siehe GDIPlusConstants.au3) enthalten.

Siehe auch

Suche nach GdipGraphicsClear in der MSDN Bibliothek.

Beispiel

#include <GDIPlus.au3>
#include <GUIConstantsEx.au3>
#include <ScreenCapture.au3>
#include <WinAPIHObj.au3>

Example()

Func Example()
    Local $hBitmap, $hImage, $hGraphic

    ; Initialisiert (startet) Microsoft Windows GDI+
    _GDIPlus_Startup()

    ; Erstellt von einem Bereich einen Screenshot
    $hBitmap = _ScreenCapture_Capture("", 0, 0, 400, 300)
    $hImage = _GDIPlus_BitmapCreateFromHBITMAP($hBitmap)

    ; Färbt ein Grafik-Objekt in einem vollfarbigen Schwarz
    $hGraphic = _GDIPlus_ImageGetGraphicsContext($hImage)
    _GDIPlus_GraphicsClear($hGraphic)

    ; Speichert das neue Bild
    _GDIPlus_ImageSaveToFile($hImage, @MyDocumentsDir & "\GDIPlus_Image.jpg")

    ; Ressourcen freigeben
    _GDIPlus_GraphicsDispose($hGraphic)
    _GDIPlus_ImageDispose($hImage)
    _WinAPI_DeleteObject($hBitmap)

    ; Gibt die durch Microsoft Windows GDI+ verwendeten Ressourcen wieder frei
    _GDIPlus_Shutdown()

    ShellExecute(@MyDocumentsDir & "\GDIPlus_Image.jpg")
EndFunc   ;==>Example