_GUICtrlEdit_GetLineCount
Beschreibung anzeigen in
Ermittelt die Anzahl von Zeilen
#include <GuiEdit.au3>
_GUICtrlEdit_GetLineCount ( $hWnd )
Parameter
| $hWnd | Control-ID / Handle des Controls |
Rückgabewert
| Erfolg: | die gesamte Anzahl von Textzeilen |
| Fehler: | 1 |
Bemerkungen
Falls das Control keinen Text enthält, ist der Rückgabewert 1. Der Rückgabewert wird nie weniger als 1 sein.
_GUICtrlEdit_GetLineCount() ermittelt die gesamte Anzahl von Textzeilen, nicht nur die Anzahl von Zeilen, die gerade sichtbar sind.
Falls das Textumbruch Feature aktiviert ist, kann die Anzahl von Zeilen geändert werden, wenn die Abmessungen der zu ändernden Fenster geändert werden
- - - - - - - - Erklärung der Controls - - - - - - - -
Beispiel
#include <GUIConstantsEx.au3>
#include <GuiEdit.au3>
#include <GuiStatusBar.au3>
Example()
Func Example()
Local $hStatusBar, $idEdit, $hGui
Local $sWow64 = ""
If @AutoItX64 Then $sWow64 = "\Wow6432Node"
Local $sFile = RegRead("HKEY_LOCAL_MACHINE\SOFTWARE" & $sWow64 & "\AutoIt v3\AutoIt", "InstallDir") & "\include\changelog.txt"
; Erstellt eine GUI
$hGui = GUICreate("Edit: Ermittelt die Zeilenanzahl", 400, 300)
$idEdit = GUICtrlCreateEdit("", 2, 2, 394, 268)
$hStatusBar = _GUICtrlStatusBar_Create($hGui, -1)
GUISetState(@SW_SHOW)
_GUICtrlEdit_SetText($idEdit, FileRead($sFile))
_GUICtrlStatusBar_SetIcon($hStatusBar, 0, 97, "shell32.dll")
_GUICtrlStatusBar_SetText($hStatusBar, @TAB & "Zeilen: " & _GUICtrlEdit_GetLineCount($idEdit))
; Die Schleife wiederholt sich, bis der Benutzer die Beenden-Aktion der GUI auslöst.
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
GUIDelete()
EndFunc ;==>Example