Funktionreferenz

_GUICtrlMonthCal_SetCurSel

Beschreibung anzeigen in

Setzt das aktuell ausgewählte Datum

#include <GuiMonthCal.au3>
_GUICtrlMonthCal_SetCurSel ( $hWnd, $iYear, $iMonth, $iDay )

Parameter

$hWnd Control-ID / Handle des Controls
$iYear Wert für Jahr
$iMonth Wert für Monat
$iDay Wert für Tag

Rückgabewert

Erfolg: True
Fehler: False

Bemerkungen

- - - - - - - - Erklärung der Controls - - - - - - - -

Verwandte Funktionen

_GUICtrlMonthCal_GetCurSel

Beispiel

#include <GuiConstantsEx.au3>
#include <GuiMonthCal.au3>
#include <WindowsConstants.au3>

Global $g_idMemo

Example()

Func Example()
    ; Erstellt eine GUI
    GUICreate("MonthCal: Setzt und ermittelt das aktuell ausgewählte Datum (v" & @AutoItVersion & ")", 600, 300)
    Local $idMonthCal = GUICtrlCreateMonthCal("", 4, 4, -1, -1, $WS_BORDER, 0x00000000)

    ; Erstellt ein Memo Control
    $g_idMemo = GUICtrlCreateEdit("", 4, 168, 392, 128, 0)
    GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")
    GUISetState(@SW_SHOW)

    ; Ermittelt/Setzt das ausgewählte Datum
    _GUICtrlMonthCal_SetCurSel($idMonthCal, @YEAR, 8, 19)
    Local $tTime = _GUICtrlMonthCal_GetCurSel($idMonthCal)
    MemoWrite("Aktuell ausgewähltes Datum : " & StringFormat("%02d/%02d/%04d", DllStructGetData($tTime, "Month"), _
            DllStructGetData($tTime, "Day"), _
            DllStructGetData($tTime, "Year")))

    ; Die Schleife wiederholt sich, bis der Benutzer eine Beenden-Aktion auslöst
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example

; Schreibt eine Nachricht in das Memo
Func MemoWrite($sMessage)
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite