Funktionreferenz

_GUICtrlMonthCal_SetMonthDelta

Beschreibung anzeigen in

Setzt die Datumsdifferenz für ein MonthCal-Control

#include <GuiMonthCal.au3>
_GUICtrlMonthCal_SetMonthDelta ( $hWnd, $iDelta )

Parameter

$hWnd Control-ID / Handle des Controls
$iDelta Wert der die Anzahl von Monaten enthält, die wie die Datumsdifferenz des Controls gesetzt werden sollen
Falls dieser Wert 0 ist, wird das Monatsdelta auf den Standard zurückgesetzt, welches die Anzahl von dargestellten Monaten im Control ist

Rückgabewert

Erfolg: Integer Wert der die Anzahl der vorherigen Datumsdifferenz enthält

Bemerkungen

- - - - - - - - Erklärung der Controls - - - - - - - -

Verwandte Funktionen

_GUICtrlMonthCal_GetMonthDelta

Beispiel

#include <GuiConstantsEx.au3>
#include <GuiMonthCal.au3>
#include <WindowsConstants.au3>

Global $g_idMemo

Example()

Func Example()
    ; Erstellt eine GUI
    GUICreate("MonthCal: Setzt und ermittelt die Datumsdifferenz (v" & @AutoItVersion & ")", 520, 300)
    Local $idMonthCal = GUICtrlCreateMonthCal("", 4, 4, -1, -1, BitOR($WS_BORDER, $MCS_MULTISELECT), 0x00000000)

    ; Erstellt ein Memo Control
    $g_idMemo = GUICtrlCreateEdit("", 4, 168, 412, 128, 0)
    GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")
    GUISetState(@SW_SHOW)

    ; Ermittelt/Setzt die Datumsdifferenz
    _GUICtrlMonthCal_SetMonthDelta($idMonthCal, 2)
    MemoWrite("Datumsdifferenz: " & _GUICtrlMonthCal_GetMonthDelta($idMonthCal))

    ; Die Schleife wiederholt sich, bis der Benutzer die Beenden-Aktion der GUI auslöst.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example

; Schreibt eine Nachricht in das Memo
Func MemoWrite($sMessage)
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite