Setzt die Auswahl für eine MonthCal-Control auf einen festgelegten Datumsbereich
#include <GuiMonthCal.au3>
_GUICtrlMonthCal_SetSelRange ( $hWnd, $iMinYear, $iMinMonth, $iMinDay, $iMaxYear, $iMaxMonth, $iMaxDay )
$hWnd | Control-ID / Handle des Controls |
$iMinYear | Minimales Jahr |
$iMinMonth | Minimaler Monat |
$iMinDay | Minimaler Tag |
$iMaxYear | Maximales Jahr |
$iMaxMonth | Maximaler Monat |
$iMaxDay | Maximaler Tag |
Erfolg: | True |
Fehler: | False |
Diese Funktion funktioniert nicht, wenn der Stil $MCS_MULTISELECT nicht verwendet wurde
- - - - - - - - Erklärung der Controls - - - - - - - -
#include <GuiConstantsEx.au3>
#include <GuiMonthCal.au3>
#include <WindowsConstants.au3>
Global $g_idMemo
Example()
Func Example()
; Erstellt eine GUI
GUICreate("MonthCal: Setzt und ermittelt die obere und untere Begrenzung des momentan ausgewählten Datumbereichs (v" & @AutoItVersion & ")", 800, 300)
Local $idMonthCal = GUICtrlCreateMonthCal("", 4, 4, -1, -1, BitOR($WS_BORDER, $MCS_MULTISELECT), 0x00000000)
; Erstellt ein Memo Control
$g_idMemo = GUICtrlCreateEdit("", 4, 168, 392, 128, 0)
GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")
GUISetState(@SW_SHOW)
; Ermittelt/Setzt die obere und untere Begrenzung des momentan ausgewählten Datumbereichs
_GUICtrlMonthCal_SetSelRange($idMonthCal, @YEAR, @MON, 1, @YEAR, @MON, 7)
Local $tRange = _GUICtrlMonthCal_GetSelRange($idMonthCal)
MemoWrite("Startdatum: " & StringFormat("%02d/%02d/%04d", DllStructGetData($tRange, "MinMonth"), _
DllStructGetData($tRange, "MinDay"), _
DllStructGetData($tRange, "MinYear")))
MemoWrite("Enddatum .: " & StringFormat("%02d/%02d/%04d", DllStructGetData($tRange, "MaxMonth"), _
DllStructGetData($tRange, "MaxDay"), _
DllStructGetData($tRange, "MaxYear")))
; Die Schleife wiederholt sich, bis der Benutzer die Beenden-Aktion der GUI auslöst.
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
GUIDelete()
EndFunc ;==>Example
; Schreibt eine Nachricht in das Memo
Func MemoWrite($sMessage)
GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc ;==>MemoWrite