Funktionreferenz

_GUICtrlStatusBar_Destroy

Beschreibung anzeigen in

Löscht das Control

#include <GuiStatusBar.au3>
_GUICtrlStatusBar_Destroy ( ByRef $hWnd )

Parameter

$hWnd Handle des Controls

Rückgabewert

Erfolg: True, $hWnd wird auf 0 gesetzt
Fehler: False
@error: 1 - Es ist nicht erlaubt, andere Anwendungssteuerelemente zu zerstören.
2 - $hWnd ist kein Header Control.

Bemerkungen

Funktioniert nur mit einem StatusBar-Control welches mit _GUICtrlStatusBar_Create() erstellt wurde

- - - - - - - - Erklärung der Controls - - - - - - - -

Verwandte Funktionen

_GUICtrlStatusBar_Create

Beispiel

Beispiel 1

#include "Extras\HelpFileInternals.au3"

#include <GUIConstantsEx.au3>
#include <GuiStatusBar.au3>
#include <MsgBoxConstants.au3>

Example()

Func Example()
    ; Erstellt eine GUI
    Local $hGUI = GUICreate("StatusBar: Löschen (v" & @AutoItVersion & ")", 400, 300, 100, 100)

    ; Standard ist 1 Abschnitt und kein Text
    Local $hStatus = _GUICtrlStatusBar_Create($hGUI)

    ; Erstellt ein Memo Control
    _MemoCreate(2, 8, 444, 259)


    Local $aParts[3] = [75, 150, -1]
    _GUICtrlStatusBar_SetParts($hStatus, $aParts)
    _GUICtrlStatusBar_SetText($hStatus, "Abschnitt 0")
    _GUICtrlStatusBar_SetText($hStatus, "Abschnitt 1", 1)
    _GUICtrlStatusBar_SetText($hStatus, "Abschnitt 2", 2)

    GUISetState(@SW_SHOW)

    Local $hHandleBefore = $hStatus
    _MemoMsgBox($MB_SYSTEMMODAL, "Information", "Das Control des folgenden Handles wird gelöscht: " & $hStatus)
    _MemoMsgBox($MB_SYSTEMMODAL, "Information", "Control gelöscht: " & _GUICtrlStatusBar_Destroy($hStatus) & @CRLF & _
            "Handle vor dem löschen: " & $hHandleBefore & @CRLF & _
            "Handle nach dem löschen: " & $hStatus)

    _MemoMsgBoxStatus("", -1, $hGUI) ; Keine weiteren Aktionen, es wird gewartet bis die GUI geschlossen wird.

    ; Die Schleife wiederholt sich, bis der Benutzer die Beenden-Aktion der GUI auslöst.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example

Example 2 : StatusBar Destroy to an External process

#include "Extras\HelpFileInternals.au3"

#include <GuiStatusBar.au3>

Example()

Func Example()
    Local $sFromTo
    Local $hWin = _MemoRunAU3OutProcess($sFromTo, True, "_GUICtrlStatusBar_Create")

    Local $hStatus = _MemoCreateOutProcess($hWin, "msctls_statusbar32", 0, $sFromTo)

    _GUICtrlStatusBar_Destroy($hStatus)
    If @error Then _MemoWrite("_GUICtrlStatusBar_Destroy()" & " @error = " & @error & @CRLF & _
            @TAB & "cannot be retrieved by an external process")

    _MemoMsgBoxStatus("", Default, $hWin) ; no more action, wait GUI for closing, close also OutProcess GUI

EndFunc   ;==>Example