_GUICtrlStatusBar_GetTipText

Beschreibung anzeigen in

Ermittelt den ToolTip-Text für einen Abschnitt

#include <GuiStatusBar.au3>
_GUICtrlStatusBar_GetTipText ( $hWnd, $iPart )

Parameter

$hWnd	Handle des Controls
$iPart	0-basierender Abschnittsindex

Rückgabewert

Gibt den Abschnittstext zurück

Bemerkungen

Die Statusbar muss mit dem Stil $SBARS_TOOLTIPS erstellt worden sein, um ToolTips zu aktivieren

- - - - - - - - Erklärung der Controls - - - - - - - -

Beispiel

Beispiel 1

#include "Extras\HelpFileInternals.au3"

#include <GUIConstantsEx.au3>
#include <GuiStatusBar.au3>
#include <WinAPIIcons.au3>

Example1()

Func Example1()
    ; Erstellt eine GUI
    Local $hGUI = GUICreate("StatusBar: Ermittelt den Tiptext (v" & @AutoItVersion & ")", 450, 320, 100, 100)
    Local $hStatus = _GUICtrlStatusBar_Create($hGUI, -1, "", $SBARS_TOOLTIPS)

    ; Erstellt ein Memo Control
    _MemoCreate(2, 8, 444, 259)
    GUISetState(@SW_SHOW)

    ; Setzt die Abschnitte
    Local $aParts[4] = [75, 150, 300, 400]
    _GUICtrlStatusBar_SetParts($hStatus, $aParts)
    _GUICtrlStatusBar_SetText($hStatus, "Erzwungene Tips werden anzeigt, wenn der Text nicht in die Box passt", 1)

    ; Setzt das Icon
    Local $hIcon = _WinAPI_LoadShell32Icon(23)
    _GUICtrlStatusBar_SetIcon($hStatus, 0, $hIcon)

    ; Setzt den Tiptext
    _GUICtrlStatusBar_SetTipText($hStatus, 0, "Tip funktioniert, wenn nur das Icon in dem Abschnitt oder Text die Abschnitte überschreitet")
    _GUICtrlStatusBar_SetTipText($hStatus, 1, "Erzwungene Tips werden anzeigt, wenn der Text nicht in die Box passt")

    _MemoWrite("Den Mauszeiger über den Abschnitten halten, um den Tipp anzuzeigen." & @CRLF)

    ; Zeigt den Tiptext
    _MemoWrite("Tiptext 0 .: " & _GUICtrlStatusBar_GetTipText($hStatus, 0) & @CRLF)
    _MemoWrite("Tiptext 1 .: " & _GUICtrlStatusBar_GetTipText($hStatus, 1))

    _MemoMsgBoxStatus("", -1, $hGUI) ; Keine weiteren Aktionen, es wird gewartet bis die GUI geschlossen wird.

    ; Die Schleife wiederholt sich, bis der Benutzer die Beenden-Aktion der GUI auslöst.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    ; Free icons
    _WinAPI_DestroyIcon($hIcon)
    GUIDelete()
EndFunc   ;==>Example1

Beispiel 2 direkte Verwendung der Symboldatei

#include "Extras\HelpFileInternals.au3"

#include <GUIConstantsEx.au3>
#include <GuiStatusBar.au3>

Example()

Func Example()
    ; Erstellt eine GUI
    Local $hGUI = GUICreate("StatusBar: Ermittelt den Tiptext (v" & @AutoItVersion & ")", 450, 320, 100, 100)
    Local $hStatus = _GUICtrlStatusBar_Create($hGUI, -1, "", $SBARS_TOOLTIPS)

    ; Erstellt ein Memo Control
    _MemoCreate(2, 8, 444, 259)
    GUISetState(@SW_SHOW)

    ; Setzt die Abschnitte
    Local $aParts[4] = [75, 150, 300, 400]
    _GUICtrlStatusBar_SetParts($hStatus, $aParts)
    _GUICtrlStatusBar_SetText($hStatus, "Erzwungene Tips werden anzeigt, wenn der Text nicht in die Box passt", 1)

    ; Setzt das Icon
    _GUICtrlStatusBar_SetIcon($hStatus, 0, 23, "shell32.dll")

    ; Setzt den Tiptext
    _GUICtrlStatusBar_SetTipText($hStatus, 0, "Tip funktioniert, wenn nur das Icon in dem Abschnitt oder Text die Abschnitte überschreitet")
    _GUICtrlStatusBar_SetTipText($hStatus, 1, "Erzwungene Tips werden anzeigt, wenn der Text nicht in die Box passt")

    _MemoWrite("Den Mauszeiger über den Abschnitten halten, um den Tipp anzuzeigen." & @CRLF)

    ; Zeigt den Tiptext
    _MemoWrite("Tiptext 0 .: " & _GUICtrlStatusBar_GetTipText($hStatus, 0) & @CRLF)
    _MemoWrite("Tiptext 1 .: " & _GUICtrlStatusBar_GetTipText($hStatus, 1))

    _MemoMsgBoxStatus("", -1, $hGUI) ; Keine weiteren Aktionen, es wird gewartet bis die GUI geschlossen wird.

    ; Die Schleife wiederholt sich, bis der Benutzer die Beenden-Aktion der GUI auslöst.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example

Example 2 : StatusBar Get/Set Tip Text to an External process

#include "Extras\HelpFileInternals.au3"

#include <GuiStatusBar.au3>

Example()

Func Example()
    Local $sFromTo
    Local $hWin = _MemoRunAU3OutProcess($sFromTo)

    Local $hStatus = _MemoCreateOutProcess($hWin, "msctls_statusbar32", 0, $sFromTo)

    Local $iPart = 0
    _GUICtrlStatusBar_SetTipText($hStatus, $iPart, "UPD 0") ; update the external Process StatusBar part 0

    _MemoWrite(@CRLF & "=====================" & @CRLF & "StatusBar info displayed" & $sFromTo & " External process" & @CRLF & "=====================")
    ; Show part text
    _MemoWrite("Part " & $iPart & " TipText ........: " & _GUICtrlStatusBar_GetTipText($hStatus, $iPart))

    _MemoWrite(@CRLF & "=====================")

    _MemoMsgBoxStatus("", Default, $hWin) ; no more action, wait GUI for closing, close also OutProcess GUI

EndFunc   ;==>Example

Funktionreferenz