Funktionreferenz


_GUICtrlStatusBar_SetBkColor

Beschreibung anzeigen in

Setzt die Hintergrundfarbe

#include <GuiStatusBar.au3>
_GUICtrlStatusBar_SetBkColor ( $hWnd, $iColor )

Parameter

$hWnd Handle des Controls
$iColor Neue Hintergrundfarbe. Legt den CLR_DEFAULT Wert fest, welcher bewirkt, dass die Statusbar seine eigene Hintergrundfarbe verwendet.

Rückgabewert

Gibt die vorherige Hintergrundfarbe oder CLR_DEFAULT falls die Hintergrundfarbe die Standardfarbe ist zurück

Bemerkungen

Gibt die RGB COLORREF Farbe zurück. Die Farbe muss in BGR Hex Farbe oder RGB COLORREF sein.
StatusBar Controls können nicht gezeichnet werden, wenn der "Windows XP Style" verwendet wird.
Manche Themen verhindern auch, dass die Statusleiste gefärbt wird. Falls die Funktion nicht korrekt arbeitet, sollte man versuchen das Thema durch die Verwendung von _WinAPI_SetWindowTheme() zu entfernen. Dabei muss bei dem Parameter ein leerer String eingegeben werden.

- - - - - - - - Erklärung der Controls - - - - - - - -

Beispiel

#include <ColorConstants.au3>
#include <GUIConstantsEx.au3>
#include <GuiStatusBar.au3>
#include <WinAPITheme.au3>

Example()

Func Example()
    ; Erstellt eine GUI
    Local $hGUI = GUICreate("StatusBar: Setzt die Hintergrundfarbe (v" & @AutoItVersion & ")", 400, 300)
    Local $hStatus = _GUICtrlStatusBar_Create($hGUI)
    GUISetState(@SW_SHOW)

    ; um das Ändern der Hintergrundeinstellung zumindest unter Windows 10 zu erlauben
    _WinAPI_SetWindowTheme($hStatus, "", "")

    ; Setzt die Abschnitte
    Local $aParts[3] = [75, 150, -1]
    _GUICtrlStatusBar_SetParts($hStatus, $aParts)
    _GUICtrlStatusBar_SetText($hStatus, "Abschnitt 0")
    _GUICtrlStatusBar_SetText($hStatus, "Abschnitt 1", 1)
    _GUICtrlStatusBar_SetText($hStatus, "Abschnitt 2", 2)

    ; Setzt die Hintergrundfarbe
    _GUICtrlStatusBar_SetBkColor($hStatus, $CLR_DARKSEAGREEN)

    ; Die Schleife wiederholt sich, bis der Benutzer die Beenden-Aktion der GUI auslöst.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example