Funktionreferenz

_GUICtrlToolbar_AddBitmap

Beschreibung anzeigen in

Fügt ein neues Bilder der Imagelist hinzu

#include <GuiToolBar.au3>
_GUICtrlToolbar_AddBitmap ( $hWnd, $iButtons, $hInst, $iID )

Parameter

$hWnd Handle des Controls
$iButtons Anzahl von Buttonbildern in dem Bitmap
$hInst Handle zu der modularen Instanz mit der ausführbaren Datei welche eine Bitmap Ressource enthält.
    Um das Bitmaphandle anstelle der Ressourcen-ID zu nutzen, ist dies auf 0 zu setzen. Man kann systemdefinierte Buttonbitmaps der Liste durch -1 hinzufügen, so wie der hInst Member und einer der folgenden Werte wie der iID Member:
    $IDB_STD_LARGE_COLOR - Fügt große, farbige Standardbitmaps hinzu
    $IDB_STD_SMALL_COLOR - Fügt kleine, farbige Standardbitmaps hinzu
    $IDB_VIEW_LARGE_COLOR - Fügt große, farbige Ansichtsbitmaps hinzu
    $IDB_VIEW_SMALL_COLOR - Fügt kleine, farbige Ansichtsbitmaps hinzu
$iID Falls $hInst 0 ist, ist dieser Member auf das Bitmaphandle des Bitmaps mit dem Buttonbild zu setzen.
    Sonst ist die Ressourcen-ID des Bitmaps mit dem Buttonbild zu setzen
    Die folgenden sind Ressourcen-IDs der Standard und Ansichtsbitmaps:
    $STD_COPY - kopieren
    $STD_CUT - ausschneiden
    $STD_DELETE - löschen
    $STD_FILENEW - neue Datei
    $STD_FILEOPEN - Datei öffnen
    $STD_FILESAVE - Dateispeichern
    $STD_FIND - suchen
    $STD_HELP - Hilfe
    $STD_PASTE - einfügen
    $STD_PRINT - drucken
    $STD_PRINTPRE - Druckvorschau
    $STD_PROPERTIES - Eigenschaften
    $STD_REDOW - wiederholen
    $STD_REPLACE - ersetzen
    $STD_UNDO - Rückgängig
    $VIEW_DETAILS - Detailansicht
    $VIEW_LARGEICONS - Große Symbole
    $VIEW_LIST - Listenansicht
    $VIEW_SMALLICONS - Kleine Symbole.
    $VIEW_SORTDATE - nach Datum sortieren.
    $VIEW_SORTNAME - nach Name sortieren.
    $VIEW_SORTSIZE - nach Größe sortieren.
    $VIEW_SORTTYPE - nach Typ sortieren.

Rückgabewert

Erfolg: Der 0-basierende Index des ersten neuen Bildes.
Fehler: -1.

Bemerkungen

- - - - - - - - Erklärung der Controls - - - - - - - -

Verwandte Funktionen

_GUICtrlToolbar_LoadBitmap

Beispiel

#include <GUIConstantsEx.au3>
#include <GuiToolbar.au3>
#include <WinAPIConstants.au3>
#include <WindowsConstants.au3>


Example()

Func Example()
    ; Erstellt eine GUI
    Local $hGUI = GUICreate("Toolbar_ Bitmap hinzufügen (v" & @AutoItVersion & ")", 400, 300)
    Local $hToolbar = _GUICtrlToolbar_Create($hGUI)
    GUISetState(@SW_SHOW)

    ; Setzt das ANSI Format
;~     _GUICtrlToolbar_SetUnicodeFormat($hToolbar, False)

    ; Fügt die Standard Systembitmaps hinzu
    _GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_LARGE_COLOR)

    ; Fügt die Buttons hinzu
    Local Enum $e_idNew = 1000, $e_idOpen, $e_idSave, $idHelp
    _GUICtrlToolbar_AddButton($hToolbar, $e_idNew, $STD_FILENEW)
    _GUICtrlToolbar_AddButton($hToolbar, $e_idOpen, $STD_FILEOPEN)
    _GUICtrlToolbar_AddButton($hToolbar, $e_idSave, $STD_FILESAVE)
    _GUICtrlToolbar_AddButtonSep($hToolbar)
    _GUICtrlToolbar_AddButton($hToolbar, $idHelp, $STD_HELP)

    ; Die Schleife wiederholt sich, bis der Benutzer die Beenden-Aktion der GUI auslöst.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example