Funktionreferenz

_GUICtrlTreeView_Destroy

Beschreibung anzeigen in

Löscht das Control

#include <GuiTreeView.au3>
_GUICtrlTreeView_Destroy ( ByRef $hWnd )

Parameter

$hWnd Control-ID / Handle des Controls

Rückgabewert

Erfolg: True, Handle wird auf 0 gesetzt
Fehler: False

Bemerkungen

Funktioniert nur mit TreeView-Controls, welche mit _GUICtrlTreeView_Create() erstellt wurden

- - - - - - - - Erklärung der Controls - - - - - - - -

Verwandte Funktionen

_GUICtrlTreeView_Create

Beispiel

#include <GUIConstantsEx.au3>
#include <GuiTreeView.au3>
#include <MsgBoxConstants.au3>
#include <WindowsConstants.au3>

Example()

Func Example()
    Local $hGUI = GUICreate("(UDF) TreeView: Löschen (v" & @AutoItVersion & ")", 400, 300)

    Local $iStyle = BitOR($TVS_EDITLABELS, $TVS_HASBUTTONS, $TVS_HASLINES, $TVS_LINESATROOT, $TVS_DISABLEDRAGDROP, $TVS_SHOWSELALWAYS, $TVS_CHECKBOXES)
    Local $hTreeView = _GUICtrlTreeView_Create($hGUI, 2, 2, 396, 268, $iStyle, $WS_EX_CLIENTEDGE)
    GUISetState(@SW_SHOW)

    _GUICtrlTreeView_BeginUpdate($hTreeView)
    Local $hItem
    For $x = 0 To Random(2, 10, 1)
        $ahItem = _GUICtrlTreeView_Add($hTreeView, 0, StringFormat("[%02d] Neues Item", $x))
        For $y = 0 To Random(2, 10, 1)
            _GUICtrlTreeView_AddChild($hTreeView, $ahItem, StringFormat("[%02d] Neues Child", $y))
        Next
    Next
    _GUICtrlTreeView_EndUpdate($hTreeView)

    MsgBox($MB_SYSTEMMODAL, "Information", "Löscht das Treeview-Control")
    _GUICtrlTreeView_Destroy($hTreeView)

    ; Die Schleife wiederholt sich, bis der Benutzer die Beenden-Aktion der GUI auslöst.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example