Funktionreferenz

_GUICtrlTreeView_Expand

Beschreibung anzeigen in

Erweitert (aufklappen) oder reduziert (zuklappen) die Liste mit den Subitems, welche zu dem festgelegten "Parent"-Item gehören

#include <GuiTreeView.au3>
_GUICtrlTreeView_Expand ( $hWnd [, $hItem = Null [, $bExpand = True]] )

Parameter

$hWnd Control-ID / Handle des Controls
$hItem [optional] Handle des Items. Standard 0 bedeutet alle Items werden aufgeklappt
$bExpand [optional] Erweitern oder reduzieren, folgende Werte verwenden:
    True - Erweitert Items
    False - Reduziert Items

Rückgabewert

Keine.

Bemerkungen

- - - - - - - - Erklärung der Controls - - - - - - - -

Verwandte Funktionen

_GUICtrlTreeView_ExpandedOnce, _GUICtrlTreeView_GetExpanded

Beispiel

#include <GUIConstantsEx.au3>
#include <GuiTreeView.au3>
#include <MsgBoxConstants.au3>
#include <WindowsConstants.au3>

Example()

Func Example()
    GUICreate("TreeView: Erweitern (v" & @AutoItVersion & ")", 400, 300)

    Local $iStyle = BitOR($TVS_EDITLABELS, $TVS_HASBUTTONS, $TVS_HASLINES, $TVS_LINESATROOT, $TVS_DISABLEDRAGDROP, $TVS_SHOWSELALWAYS, $TVS_CHECKBOXES)
    Local $idTreeView = GUICtrlCreateTreeView(2, 2, 396, 268, $iStyle, $WS_EX_CLIENTEDGE)
    GUISetState(@SW_SHOW)

    ; Setzt das ANSI Format
;~     _GUICtrlTreeView_SetUnicodeFormat($idTreeView, False)

    _GUICtrlTreeView_BeginUpdate($idTreeView)
    Local $aidItem[5]
    For $x = 0 To 4
        $aidItem[$x] = GUICtrlCreateTreeViewItem(StringFormat("[%02d] Neues Item", $x), $idTreeView)
        For $y = 0 To 2
            GUICtrlCreateTreeViewItem(StringFormat("[%02d] Neues Item", $y), $aidItem[$x])
        Next
    Next
    _GUICtrlTreeView_EndUpdate($idTreeView)

    MsgBox($MB_SYSTEMMODAL, "Information", "alle erweitern")
    _GUICtrlTreeView_Expand($idTreeView)

    MsgBox($MB_SYSTEMMODAL, "Information", "alle zuklappen")
    _GUICtrlTreeView_Expand($idTreeView, 0, False)

    MsgBox($MB_SYSTEMMODAL, "Information", "Item 1 erweitern")
    _GUICtrlTreeView_Expand($idTreeView, $aidItem[1])

    MsgBox($MB_SYSTEMMODAL, "Information", "Item 1 zuklappen")
    _GUICtrlTreeView_Expand($idTreeView, $aidItem[1], False)

    ; Die Schleife wiederholt sich, bis der Benutzer die Beenden-Aktion der GUI auslöst.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example