Funktionreferenz

_GUICtrlTreeView_GetVisibleCount

Beschreibung anzeigen in

Gibt die Anzahl von Items zurück, die komplett sichtbar sind

#include <GuiTreeView.au3>
_GUICtrlTreeView_GetVisibleCount ( $hWnd )

Parameter

$hWnd Control-ID / Handle des Controls

Rückgabewert

Gibt die maximale Anzahl von komplett sichtbaren Items im Control zurück

Bemerkungen

Die Anzahl von komplett sichtbaren Items kann größer sein als die Anzahl von Items im Control.
Das Control berechnet diesen Wert durch die Teilung von der Höhe des Fensters durch die Höhe eines Items.
Es ist zu beachten, dass der zurückgegebene Wert, die Anzahl von komplett sichtbaren Items ist.
Falls man alle 20 Items und einen Teil von mehr Items sieht, ist der Rückgabewert 20 und nicht 21.

- - - - - - - - Erklärung der Controls - - - - - - - -

Beispiel

#include <GUIConstantsEx.au3>
#include <GuiTreeView.au3>
#include <MsgBoxConstants.au3>
#include <WindowsStylesConstants.au3>

Example()

Func Example()
    GUICreate("TreeView: Gibt die Anzahl von Items zurück, die komplett sichtbar sind (v" & @AutoItVersion & ")", 600, 300)

    Local $iStyle = BitOR($TVS_EDITLABELS, $TVS_HASBUTTONS, $TVS_HASLINES, $TVS_LINESATROOT, $TVS_DISABLEDRAGDROP, $TVS_SHOWSELALWAYS)
    Local $idTreeView = GUICtrlCreateTreeView(2, 2, 396, 268, $iStyle, $WS_EX_CLIENTEDGE)
    GUISetState(@SW_SHOW)

    _GUICtrlTreeView_BeginUpdate($idTreeView)
    For $x = 0 To 99
        _GUICtrlTreeView_Add($idTreeView, 0, StringFormat("[%02d] Neues Item", $x))
    Next
    _GUICtrlTreeView_EndUpdate($idTreeView)

    MsgBox($MB_SYSTEMMODAL, "Information", "Sichtbar: " & _GUICtrlTreeView_GetVisibleCount($idTreeView))

    ; Die Schleife wiederholt sich, bis der Benutzer die Beenden-Aktion der GUI auslöst.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example