Wählt das festgelegte Item aus, scrollt das Item in die Ansicht oder zeichnet das Item neu
#include <GuiTreeView.au3>
_GUICtrlTreeView_SelectItem ( $hWnd, $hItem [, $iFlag = 0] )
$hWnd | Control-ID / Handle des Controls |
$hItem | Handle des Items |
$iFlag | [optional] Aktionsflag: $TVGN_CARET - Setzt die Auswahl auf das festgelegte Item $TVGN_DROPHILITE - Zeichnet das festgelegte Item gemäß dem Stil neu, um das Ziel der drag-and-drop Aktion zu verwenden $TVGN_FIRSTVISIBLE - Scrollt das Treeview vertikal, so dass das festgelegte Item das erste sichtbare Item ist |
Erfolg: | True |
Fehler: | False |
Der hier gesetzte Status kann nur durch die Funktion _GUICtrlTreeView_GetSelection ermittelt werden.
Es kann nur ein Item ausgewählt sein.
- - - - - - - - Erklärung der Controls - - - - - - - -
#AutoIt3Wrapper_UseX64=Y
#include <GuiConstantsEx.au3>
#include <GuiTreeView.au3>
#include <WindowsConstants.au3>
Example()
Func Example()
GUICreate("TreeView: Item auswählen (v" & @AutoItVersion & ")", 400, 300)
Local $iStyle = BitOR($TVS_EDITLABELS, $TVS_HASBUTTONS, $TVS_HASLINES, $TVS_LINESATROOT, $TVS_DISABLEDRAGDROP, $TVS_SHOWSELALWAYS)
Local $idTreeView = GUICtrlCreateTreeView(2, 2, 396, 268, $iStyle, $WS_EX_CLIENTEDGE)
GUISetState(@SW_SHOW)
_GUICtrlTreeView_BeginUpdate($idTreeView)
Local $aidItem[10], $aidChildItem[30], $iYItem = 0
For $x = 0 To 9
$aidItem[$x] = GUICtrlCreateTreeViewItem(StringFormat("[%02d] Neues Item", $x), $idTreeView)
For $y = 1 To 3
$aidChildItem[$iYItem] = GUICtrlCreateTreeViewItem(StringFormat("[%02d] Neues Child", $iYItem), $aidItem[$x])
$iYItem += 1
Next
Next
_GUICtrlTreeView_EndUpdate($idTreeView)
Local $iRand = 6
_GUICtrlTreeView_SelectItem($idTreeView, $aidItem[$iRand])
MsgBox($MB_SYSTEMMODAL, "Information", "Tree für Index " & $iRand & ": " & _GUICtrlTreeView_GetTree($idTreeView, $aidItem[$iRand]))
$iRand = 5
_GUICtrlTreeView_SelectItem($idTreeView, $aidChildItem[$iRand])
; Die Schleife wiederholt sich, bis der Benutzer die Beenden-Aktion der GUI auslöst.
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
GUIDelete()
EndFunc ;==>Example