Funktionreferenz


_GUICtrlTreeView_SetCheckedByIndex

Beschreibung anzeigen in

Legt fest, ob die Checkbox eines durch seinen Index angegebenen Eintrags eines Items angehakt ist oder nicht

#include <GuiTreeView.au3>
_GUICtrlTreeView_SetCheckedByIndex ( $hWnd, $hItem, $iIndex [, $bCheck = True] )

Parameter

$hWnd Control-ID / Handle des Controls
$hItem Handle des Items
$iIndex 0-basierender Index in der $hItem Liste der Items
$bCheck [optional] zu setzender Wert für den "angehakt"-Status:
    True - angehakt
    False - nicht angehakt

Rückgabewert

Erfolg: True
Fehler: False

Bemerkungen

- - - - - - - - Erklärung der Controls - - - - - - - -

Beispiel

#include <GUIConstantsEx.au3>
#include <GuiTreeView.au3>
#include <MsgBoxConstants.au3>
#include <WindowsConstants.au3>

Example()

Func Example()
    GUICreate("TreeView: Legt durch den Index fest, ob die Checkbox angehakt ist (v" & @AutoItVersion & ")", 600, 300)

    Local $iStyle = BitOR($TVS_EDITLABELS, $TVS_HASBUTTONS, $TVS_HASLINES, $TVS_LINESATROOT, $TVS_DISABLEDRAGDROP, $TVS_SHOWSELALWAYS, $TVS_CHECKBOXES)
    Local $idTreeView = GUICtrlCreateTreeView(2, 2, 396, 268, $iStyle, $WS_EX_CLIENTEDGE)
    GUISetState(@SW_SHOW)

    ; Setzt das ANSI Format
;~     _GUICtrlTreeView_SetUnicodeFormat($idTreeView, False)

    _GUICtrlTreeView_BeginUpdate($idTreeView)
    Local $aidItem[6]
    For $x = 0 To UBound($aidItem) - 1
        $aidItem[$x] = GUICtrlCreateTreeViewItem(StringFormat("[%02d] Neues Item", $x), $idTreeView)
        For $y = 0 To 5
            GUICtrlCreateTreeViewItem(StringFormat("[%02d] Neues Child Item", $y), $aidItem[$x])
        Next
    Next
    _GUICtrlTreeView_EndUpdate($idTreeView)

    Local $hRandomItem = 5
    Local $iRandIndex = 4
    MsgBox($MB_SYSTEMMODAL, "Information", _
            StringFormat("Setzt den Child Item Index[%d] vom Itemindex[%d]: %s", $iRandIndex, $hRandomItem, _
            _GUICtrlTreeView_SetCheckedByIndex($idTreeView, $aidItem[$hRandomItem], $iRandIndex)))
    Local $hSet = _GUICtrlTreeView_GetItemByIndex($idTreeView, $aidItem[$hRandomItem], $iRandIndex)
    _GUICtrlTreeView_EnsureVisible($idTreeView, $hSet)

    ; Die Schleife wiederholt sich, bis der Benutzer die Beenden-Aktion der GUI auslöst.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example