Funktionreferenz

_GUICtrlTreeView_SetHeight

Beschreibung anzeigen in

Setzt die Höhe für jedes Item

#include <GuiTreeView.au3>
_GUICtrlTreeView_SetHeight ( $hWnd, $iHeight )

Parameter

$hWnd Control-ID / Handle des Controls
$iHeight Neue Höhe in Pixel für jedes Item. Höhen weniger als 1 werden auf 1 gesetzt.
Falls es ein ungerader Wert ist und falls das Control den Stil $TVS_NONEVENHEIGHT nicht besitzt, werden die Werte auf den nächstkleineren Wert abgerundet.
Falls -1, wird der Standardwert verwendet.

Rückgabewert

Gibt die vorherige Höhe der Items in Pixel zurück

Bemerkungen

- - - - - - - - Erklärung der Controls - - - - - - - -

Verwandte Funktionen

_GUICtrlTreeView_GetHeight

Beispiel

#include <GUIConstantsEx.au3>
#include <GuiTreeView.au3>
#include <MsgBoxConstants.au3>
#include <WindowsStylesConstants.au3>

Example()

Func Example()
    GUICreate("TreeView: Setzt und ermittelt die Höhe (v" & @AutoItVersion & ")", 500, 300)

    Local $iStyle = BitOR($TVS_EDITLABELS, $TVS_HASBUTTONS, $TVS_HASLINES, $TVS_LINESATROOT, $TVS_DISABLEDRAGDROP, $TVS_SHOWSELALWAYS, $TVS_CHECKBOXES)
    Local $idTreeView = GUICtrlCreateTreeView(2, 2, 396, 268, $iStyle, $WS_EX_CLIENTEDGE)
    GUISetState(@SW_SHOW)

    _GUICtrlTreeView_BeginUpdate($idTreeView)
    Local $aidTVi_Item[6]
    For $x = 0 To UBound($aidTVi_Item) - 1
        $aidTVi_Item[$x] = GUICtrlCreateTreeViewItem(StringFormat("[%02d] Neues Item", $x + 1), $idTreeView)
    Next
    _GUICtrlTreeView_EndUpdate($idTreeView)

    _GUICtrlTreeView_SetHeight($idTreeView, 30)

    MsgBox($MB_SYSTEMMODAL, "Information", StringFormat("Itemhöhe? %s", _GUICtrlTreeView_GetHeight($idTreeView)))

    ; Die Schleife wiederholt sich, bis der Benutzer die Beenden-Aktion der GUI auslöst.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example