Funktionreferenz


_GUICtrlTreeView_SetScrollTime

Beschreibung anzeigen in

Setzt die maximale Scrollzeit

#include <GuiTreeView.au3>
_GUICtrlTreeView_SetScrollTime ( $hWnd, $iTime )

Parameter

$hWnd Control-ID / Handle des Controls
$iTime Neue maximale Scrollzeit in Millisekunden

Rückgabewert

Gibt die vorherige Scrollzeit in Millisekunden zurück

Bemerkungen

Die maximale Scrollzeit ist die größte Zeit die eine Scrolloperation benötigen kann.
Das Scrollen ist so eingestellt, dass der Scroll innerhalb einer maximalen Scrollzeit durchgeführt wird.
Eine Scrolloperation könnte auch weniger Zeit in Anspruch nehmen.

- - - - - - - - Erklärung der Controls - - - - - - - -

Verwandte Funktionen

_GUICtrlTreeView_GetScrollTime

Beispiel

#include <GUIConstantsEx.au3>
#include <GuiTreeView.au3>
#include <MsgBoxConstants.au3>
#include <WindowsConstants.au3>

Example()

Func Example()
    GUICreate("TreeView: Setzt und ermittelt die Scrollzeit (v" & @AutoItVersion & ")", 500, 300)

    Local $iStyle = BitOR($TVS_EDITLABELS, $TVS_HASBUTTONS, $TVS_HASLINES, $TVS_LINESATROOT, $TVS_DISABLEDRAGDROP, $TVS_SHOWSELALWAYS, $TVS_CHECKBOXES)
    Local $idTreeView = GUICtrlCreateTreeView(2, 2, 396, 268, $iStyle, $WS_EX_CLIENTEDGE)
    GUISetState(@SW_SHOW)

    _GUICtrlTreeView_BeginUpdate($idTreeView)
    Local $aidItem[10]
    For $x = 0 To 9
        $aidItem[$x] = GUICtrlCreateTreeViewItem(StringFormat("[%02d] Neues Item", $x), $idTreeView)
        For $y = 1 To Random(2, 10, 1)
            GUICtrlCreateTreeViewItem(StringFormat("[%02d] Neues Child", $y), $aidItem[$x])
        Next
    Next
    _GUICtrlTreeView_EndUpdate($idTreeView)

    _GUICtrlTreeView_SetScrollTime($idTreeView, 2)
    MsgBox($MB_SYSTEMMODAL, "Information", "Scrollzeit: " & _GUICtrlTreeView_GetScrollTime($idTreeView) & " Millisekunden")

    ; Die Schleife wiederholt sich, bis der Benutzer die Beenden-Aktion der GUI auslöst.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example