_GUICtrlTreeView_SetSelected
Beschreibung anzeigen in
Legt fest, ob das Item im markierten Zustand erscheinen soll
#include <GuiTreeView.au3>
_GUICtrlTreeView_SetSelected ( $hWnd, $hItem [, $bFlag = True] )
Parameter
| $hWnd | Control-ID / Handle des Controls |
| $hItem | Handle zu dem Item |
| $bFlag | [optional] True, falls das Item markiert werden soll, sonst False |
Rückgabewert
| Erfolg: | True |
| Fehler: | False |
Bemerkungen
Durch diese Funktion wird das Item nur "optisch" markiert. Es können so auch mehrere Items markiert werden.
Will man sicherstellen, dass nur ein Item markiert ist sollte man _GUICtrlTreeView_SelectItem verwenden.
So kann auch mit der Funktion _GUICtrlTreeView_GetSelection das einzige markierte Item ermittelt werden.
- - - - - - - - Erklärung der Controls - - - - - - - -
Verwandte Funktionen
Beispiel
#include <GUIConstantsEx.au3>
#include <GuiTreeView.au3>
#include <MsgBoxConstants.au3>
#include <WindowsConstants.au3>
Example()
Func Example()
GUICreate('TreeView: Setzt und ermittelt den "markiert"-Status eiens Items (v' & @AutoItVersion & ")", 600, 300)
Local $iStyle = BitOR($TVS_EDITLABELS, $TVS_HASBUTTONS, $TVS_HASLINES, $TVS_LINESATROOT, $TVS_DISABLEDRAGDROP, $TVS_SHOWSELALWAYS, $TVS_CHECKBOXES)
Local $idTreeView = GUICtrlCreateTreeView(2, 2, 396, 268, $iStyle, $WS_EX_CLIENTEDGE)
GUISetState(@SW_SHOW)
_GUICtrlTreeView_BeginUpdate($idTreeView)
Local $aidItem[10]
For $x = 0 To 9
$aidItem[$x] = GUICtrlCreateTreeViewItem(StringFormat("[%02d] Neues Item", $x), $idTreeView)
For $y = 1 To Random(2, 10, 1)
GUICtrlCreateTreeViewItem(StringFormat("[%02d] Neues Child", $y), $aidItem[$x])
Next
Next
_GUICtrlTreeView_EndUpdate($idTreeView)
Local $iRand = Random(0, 9, 1)
MsgBox($MB_SYSTEMMODAL, "Information", StringFormat("Index %d markiert? %s", $iRand, _GUICtrlTreeView_GetSelected($idTreeView, $aidItem[$iRand])))
_GUICtrlTreeView_SetSelected($idTreeView, $aidItem[$iRand])
MsgBox($MB_SYSTEMMODAL, "Information", StringFormat("Index %d markiert? %s", $iRand, _GUICtrlTreeView_GetSelected($idTreeView, $aidItem[$iRand])))
; Die Schleife wiederholt sich, bis der Benutzer die Beenden-Aktion der GUI auslöst.
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
GUIDelete()
EndFunc ;==>Example