_SQLite_Startup

Beschreibung anzeigen in

Lädt die SQLite3.dll

#include <SQLite.au3>
_SQLite_Startup ( [$sDll_Filename = "" [, $bUTF8ErrorMsg = False [, $iForceLocal = 0 [, $hPrintCallback = $__g_hPrintCallback_SQLite [, $bAutoItTypeConversion = False]]]]] )

Parameter

$sDll_Filename	[optional] Dll Dateiname Standard ist "sqlite3.au3" oder "sqlite3_x64.dll" im X64 Modus
$bUTF8ErrorMsg	[optional] Erzwingt, dass ConsoleWrite() UTF8 Zeichen darstellt
$iForceLocal	[optional] 1 = Nutzt die angegebene Dll-Datei. Kein Versionsvergleich. Automatisch "_x64.dll" im X64 Modus 0 (Standard)= Die Dll wird in @ScriptDir, @WorkingDir, @LocalAppDataDir & "\AutoIt v3\SQLite\", @SystemDir und @WindowsDir gesucht.
$hPrintCallback	[optional] Eine Variable die mit der Benutzerfunktion verknüpft ist, um eine SQLite Diagnose-Nachricht abzugreifen. Standard = __SQLite_ConsoleWrite(). Siehe Bemerkungen.
$bAutoItTypeConversion	[optional] Konvertierung von String in AutoItType-Variable erzwingen ((Standard = False). Siehe Bemerkungen.

Rückgabewert

Erfolg:	der Pfad zur geöffneten DLL-Datei
Fehler:	Setzt das @error Flag auf ungleich null

Bemerkungen

Wenn die #include <SQLite.dll.au3> eingebunden ist, wird die SQLite-Version geprüft.
Die SQLite-Dateien können von https://www.autoitscript.com/autoit3/pkgmgr/sqlite/sqlite3_setup_version.exe heruntergeladen werden. Abgespeichert können diese in @ScriptDir, @WorkingDir, @LocalAppDataDir & "\AutoIt v3\SQLite\" (default), @SystemDir oder @WindowsDir werden.
Zur Verwendung durch einen beliebigen Benutzer speichern Sie die SQLite-Dateien in @SystemDir oder @WindowsDir.
Um das Herunterladen der korrekten Version zu erleichtern, können Sie das Skript "Extras\AutoUpdateIt\AutoIt3SQLiteUpdate.au3" verwenden (ähnlich wie AutoUpdateIt.au3 zur Überprüfung von AutoIt Release oder Beta).

Wenn $bUTF8ErrorMsg ungleich 0 ist, so werden UTF8 formatierte Strings in die Konsole gedruckt.
Dies erlaubt es Anwendungen wie SciTE diese Zeichen darzustellen, falls es mit output.code.page=65001 konfiguriert ist.
Dies ist der Fall wenn SciTE unter einer nichtenglischen Version läuft.

Der $hPrintCallback-Parameter gibt den Namen einer benutzerdefinierten Callback-Funktion an. An diese Funktion wird ein einzelner Parameter übergeben, der die auszugebende Nachricht enthält. Die Standard-Callback-Funktion ist $__g_hPrintCallback_SQLite. Diese Funktion kann gut als Beispiel für eine eigene Callback-Funktion dienen.

$bAutoItTypeConversion ist nützlich, wenn das gesamte Skript von den _SQlite_FetchData() AutoIt-Variablen zurückgeben möchte.
Standard ist die Rückgabe von String oder Binary AutoIt Variable.

Beispiel

Beispiel 1

; die SQLite.dll Version muß passen

#include <MsgBoxConstants.au3>
#include <SQLite.au3>
#include <SQLite.dll.au3>

Local $sSQliteDll = _SQLite_Startup()

If @error Then
    MsgBox($MB_SYSTEMMODAL, "SQLite Fehler", "sqlite3.dll konnte nicht geladen werden!" & @CRLF & @CRLF & _
            "Nicht gefunden in @ScriptDir, @WorkingDir," & @CRLF & @TAB & "@LocalAppDataDir\AutoIt v3\SQLite," & @CRLF & @TAB & "@SystemDir ode @WindowsDir")
    Exit -1
EndIf
MsgBox($MB_SYSTEMMODAL, "SQLite3.dll geladen", $sSQliteDll & " (" & _SQLite_LibVersion() & ")")
ConsoleWrite("_SQLite_LibVersion=" & _SQLite_LibVersion() & @CRLF)
_SQLite_Shutdown()

Beispiel 2

; keine Versionsreferenz, deshalb muss die Datei in einem der folgenden Ordner existieren: @ScriptDir, @WorkingDir, @SystemDir oder @WindowsDir

#include <MsgBoxConstants.au3>
#include <SQLite.au3>

Local $sSQliteDll
$sSQliteDll = _SQLite_Startup()
If @error Then
    MsgBox($MB_SYSTEMMODAL, "SQLite Fehler", "SQLite3.dll konnte nicht geladen werden!" & @CRLF & @CRLF & _
            "Nicht gefunden in @ScriptDir, @WorkingDir, @SystemDir oder @WindowsDir")
    Exit -1
EndIf

MsgBox($MB_SYSTEMMODAL, "SQLite3.dll geladen", $sSQliteDll & " (" & _SQLite_LibVersion() & ")")
ConsoleWrite("_SQLite_LibVersion=" & _SQLite_LibVersion() & @CRLF)
_SQLite_Shutdown()

Beispiel 3

; öffnet SQLite mit einer festgelegten lokalen Datei

#include <MsgBoxConstants.au3>
#include <SQLite.au3>

Local $sLocalSQLiteDll = "lokale SQLite.dll" ; muss in eine existierende .dll geändert werden, da sonst ein Fehler auftritt

Local $sSQliteDll = _SQLite_Startup($sLocalSQLiteDll, False, 1)
If @error Then
    MsgBox($MB_SYSTEMMODAL, "SQLite Fehler", "SQLite3.dll konnte nicht geladen werden!")
    Exit -1
EndIf

MsgBox($MB_SYSTEMMODAL, "SQLite3.dll gealden", $sSQliteDll & " (" & _SQLite_LibVersion() & ")")
ConsoleWrite("_SQLite_LibVersion=" & _SQLite_LibVersion() & @CRLF)
_SQLite_Shutdown()

Funktionreferenz