Ruft einen Callback für eine Fenster-Unterklasse auf oder aktualisiert diesen
#include <WinAPIShellEx.au3>
_WinAPI_SetWindowSubclass ( $hWnd, $pSubclassProc, $idSubClass [, $pData = 0] )
| $hWnd | Handle des Fensters, von dem eine Unterklasse erstellt wird. |
| $pSubclassProc | Ein Zeiger auf eine Fensterprozedur. Dieser Zeiger und die Unterklassen-ID identifizieren diesen Unterklassen-Callback eindeutig. (Siehe MSDN für mehr Informationen) |
| $idSubClass | Die ID der Unterklasse. |
| $pData | [optional] Die Referenzdaten. Dieser Wert wird an die Unterklassenprozedur übergeben. Die Bedeutung dieses Werts wird von der aufrufenden Anwendung festgelegt. |
| Erfolg: | True. |
| Fehler: | False. |
Callbacks von Unterklassen werden durch die Kombination aus der Callback-Adresse und der vom Aufrufer definierten Unterklassen-ID identifiziert.
Wenn das Paar aus Callback-Adresse und ID noch nicht installiert wurde, installiert diese Funktion die Unterklasse;
andernfalls aktualisiert diese Funktion lediglich die Referenzdaten.
Suche nach SetWindowSubclass in der MSDN Bibliothek.
#include "Extras\WMDebug.au3"
#include <GUIConstantsEx.au3>
#include <WinAPIShellEx.au3>
OnAutoItExitRegister('OnAutoItExit')
; Create GUI
Global $g_hForm = GUICreate('Test ' & StringReplace(@ScriptName, '.au3', '()'))
; Register DLL callback that will be used as window subclass procedure
Global $g_hDll = DllCallbackRegister('_SubclassProc', 'lresult', 'hwnd;uint;wparam;lparam;uint_ptr;dword_ptr')
Global $g_pDll = DllCallbackGetPtr($g_hDll)
; Install window subclass callback
_WinAPI_SetWindowSubclass($g_hForm, $g_pDll, 1000, 0)
GUISetState(@SW_SHOW)
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
Func _SubclassProc($hWnd, $iMsg, $wParam, $lParam, $iID, $pData)
#forceref $iID, $pData
; Declared in WMDebug.au3
_WM_Debug($hWnd, $iMsg, $wParam, $lParam)
Return _WinAPI_DefSubclassProc($hWnd, $iMsg, $wParam, $lParam)
EndFunc ;==>_SubclassProc
Func OnAutoItExit()
_WinAPI_RemoveWindowSubclass($g_hForm, $g_pDll, 1000)
DllCallbackFree($g_hDll)
EndFunc ;==>OnAutoItExit