Funktionreferenz

_Word_DocClose

Beschreibung anzeigen in

Schließt das angegebene Word Dokument

#include <Word.au3>
_Word_DocClose ( $oDoc [, $iSaveChanges = $WdDoNotSaveChanges [, $iOriginalFormat = $WdOriginalDocumentFormat]] )

Parameter

$oDoc Word Dokument Objekt
$iSaveChanges [optional] Gibt an, ob/wie das Dokument gesichert werden soll (Standard = $WdDoNotSaveChanges).
Kann eine der folgenden Konstanten aus der WdSaveOptions Aufzählung sein:
    $WdDoNotSaveChanges, $WdPromptToSaveChanges oder $WdSaveChanges
$iOriginalFormat [optional] Gibt an, in welchem Format das Dokument gesichert werden soll.
Kann eine der folgenden Konstanten aus der WdOriginalFormat Aufzählung sein:
    $WdOriginalDocumentFormat, $WdPromptUser oder $WdWordDocument (Standard = $WdOriginalDocumentFormat)

Rückgabewert

Erfolg: 1.
Fehler: 0 und setzt das @error Flag auf ungleich null.
@error: 1 - $oDoc ist kein Objekt
2 - Fehler beim Schließen des Dokumentes. @extended wird auf den COM Fehlercode gesetzt

Verwandte Funktionen

_Word_DocAdd, _Word_DocAttach, _Word_DocOpen

Beispiel

#include <MsgBoxConstants.au3>
#include <Word.au3>

; Erzeugt ein neues oder stellt eine Verbindung zu einem bestehenden Word-Objekt her
Local $oWord = _Word_Create()
If @error <> 0 Then Exit MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocClose Beispiel", _
        "Fehler beim Erstellen des Word-Anwendungsobjektes." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
; Öffnet das Testdokument im Lese-Modus
Local $oDoc = _Word_DocOpen($oWord, @ScriptDir & "\Extras\Test.doc", Default, Default, True)
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocClose Beispiel", _
        "Fehler beim Öffnen von '.\Extras\Test.doc'." & @CRLF & "@error = " & @error & ", @extended = " & @extended)

; Schließt das Word Document
MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocClose Beispiel", "Press 'OK' to close document '.\Extras\Test.doc'.")
_Word_DocClose($oDoc)
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocClose Beispiel", _
        "Error closing document '.\Extras\Test.doc'." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocClose Beispiel", "The document has been closed successfully.")