_Word_DocAttach

Beschreibung anzeigen in

Verbindet sich mit der ersten Instanz eines Word Dokumentes mit dem passenden Suchargument (abhängig vom ausgewählten Modus)

#include <Word.au3>
_Word_DocAttach ( $oAppl, $sString [, $sMode = "FilePath" [, $iCase = 0]] )

Parameter

$oAppl	Word Objekt wie es von einem vorherigen Aufruf von _Word_Create() zurückgegeben wurde
$sString	Zu suchendes Suchargument
$sMode	[optional] Zu verwendender Suchmodus. Gültige sind: "FileName" - Name des geöffneten Dokumentes "FilePath" - Voller Pfad des geöffneten Dokumentes (Standard) "Text" - Text im Hauptteil (Body) des Dokumentes
$iCase	[optional] Gibt an, ob Groß-/Kleinschreibung im Such-Modus "Text" beachtet werden soll: 0 - Groß-/Kleinschreibung wird nicht beachtet. Dabei wird das Gebietsschema (locale) des Benutzers verwendet (Standard) 1 - Groß-/Kleinschreibung wird beachtet 2 - Groß-/Kleinschreibung wird nicht beachtet. Dabei wird einfacherer/schnellerer Algorithmus verwendet

Rückgabewert

Erfolg:	Eine Variable die auf das neue Dokumenten-Objekt verweist.
Fehler:	0 und setzt das @error Flag auf ungleich null.
@error:	1 - $oAppl ist kein Objekt 2 - $oAppl ist kein Objekt 3 - $sMode ist ungültig. Muss "FilePath", "FileName" oder "Text" sein 4 - Das Suchargument konnte nicht gefunden werden

Bemerkungen

Diese Funktion gibt nur das Objekt des gefundenen Dokumentes zurück.
Um die dazugehörige Word Instanz zu erhalten, verwenden Sie: $oAppl = $oDoc.Application.

Beispiel

Beispiel 1

#include <MsgBoxConstants.au3>
#include <Word.au3>

; Erzeugt ein neues oder stellt eine Verbindung zu einem bestehenden Word-Objekt her
Local $oWord = _Word_Create()
If @error <> 0 Then Exit MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_Attach Beispiel 1", _
        "Fehler beim Erstellen eines neuen Word-Anwendungsobjektes." & @CRLF & "@error = " & @error & ", @extended = " & @extended)

; Testdokument schreibgeschützt öffnen
_Word_DocOpen($oWord, @ScriptDir & "\Extras\Test.doc", Default, Default, True)
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocAttach Beispiel 1", "Fehler beim Öffnen von '.\Extras\Test.doc'." & _
        @CRLF & "@error = " & @error & ", @extended = " & @extended)

; An das Testdokument mit Modus "Filename" anhängen und den Fokus auf das Fenster setzen
Local $oDoc = _Word_DocAttach($oWord, "Test.doc", "Filename")
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocAttach Beispiel 1", _
        "Fehler beim Anhängen an das Dokument '.\Extras\Test.doc' im Modus 'FileName'." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
; Fokus auf das Word-Dokument setzen - Ident mit Parameter $f_takeFocus der alten Funktion _WordCreate
WinActivate($oWord.ActiveWindow.Caption & " - " & $oWord.Caption)
MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocAttach Beispiel 1", "Anhängen an das Dokument im Modus 'Filename' erfolgreich!" & @CRLF & _
        @CRLF & "Text des angehängten Dokuments:" & @CRLF & $oDoc.Range().Text)

Beispiel 2

#include <MsgBoxConstants.au3>
#include <Word.au3>

; Erzeugt ein neues oder stellt eine Verbindung zu einem bestehenden Word-Objekt her
Local $oWord = _Word_Create()
If @error <> 0 Then Exit MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocAttach Beispiel 2", _
        "Fehler beim Erstellen eines neuen Word-Anwendungsobjektes." & @CRLF & "@error = " & @error & ", @extended = " & @extended)

; Test-Dokument im Lesemodus öffnen
_Word_DocOpen($oWord, @ScriptDir & "\Extras\Test.doc", Default, Default, True)
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocAttach Beispiel 2", "Error opening '.\Extras\Test.doc'." & _
        @CRLF & "@error = " & @error & ", @extended = " & @extended)

; An das Test-Dokument im Modus "Text" anknüpfen.
Local $oDoc = _Word_DocAttach($oWord, "Test", "Text")
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocAttach Beispiel 2", _
        "Fehler beim Verknüpfen mit '\Extras\Test.doc' im Modus 'Text'." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocAttach Beispiel 2", "Verknüpfung mit dem Dokument im Modus 'Text' war erfolgreich!" & _
        @CRLF & @CRLF & "Text des verknüpften Dokumentes:" & @CRLF & $oDoc.Range().Text)

Funktionreferenz