_Word_DocGet
Beschreibung anzeigen in
Gibt eine Zusammenstellung aller Dokumente oder das Objekt eines einzelnen Dokumentes zurück
#include <Word.au3>
_Word_DocGet ( $oAppl [, $vIndex = -1] )
Parameter
| $oAppl | Word Objekt wie es von einem vorherigen Aufruf von _Word_Create() zurückgegeben wurde |
| $vIndex | [optional] Gibt an, was von der Funktion zurückgegeben werden soll: -1 - Gibt eine Zusammenstellung (Collection) aller Dokumente zurück (Standard) 0 - Gibt das aktive Dokument zurück n - Die Indexnummer des zurückzugebenden Dokumentes (der Index beginnt mit 1) x - Der Namende des zurückzugebenden Dokumentes |
Rückgabewert
| Erfolg: | Das Objekt einer Zusammenstellung (Collection) von Dokumenten oder eines einzelnen Dokumentes. @extended enthält die Anzahl an Dokumenten |
| Fehler: | 0 und setzt das @error Flag auf ungleich null. |
| @error: | 1 - $oAppl ist kein Objekt 2 - $vIndex ist ungültig (< -1 oder > Anzahl an Dokumenten (Documents.Count)) 3 - Das angegebene Dokument konnte nicht gefunden werden oder ein Fehler trat auf. @extended wird auf den COM Fehlercode gesetzt 4 - Fehler beim Zugriff auf die Liste aller Dokumente. @extended wird auf den COM Fehlercode gesetzt |
Verwandte Funktionen
Beispiel
#include <MsgBoxConstants.au3>
#include <Word.au3>
; Erzeugt ein neues oder stellt eine Verbindung zu einem bestehenden Word-Objekt her
Local $oWord = _Word_Create()
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocGet Beispiel", _
"Fehler beim Erstellen des Word-Anwendungsobjektes." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
; Öffnet das Dokument Test.doc im Lesemodus
_Word_DocOpen($oWord, @ScriptDir & "\Extras\Test.doc", Default, Default, True)
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocGet Beispiel", "Fehler beim Öffnen von '.\Extras\Test.doc'." & @CRLF & _
"@error = " & @error & ", @extended = " & @extended)
; Öffnet das Dokument Test2.doc im Lesemodus
_Word_DocOpen($oWord, @ScriptDir & "\Extras\Test2.doc", Default, Default, True)
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocGet Beispiel", "Fehler beim Öffnen von '.\Extras\Test2.doc'." & @CRLF & _
"@error = " & @error & ", @extended = " & @extended)
; Finde das erste Dokument in der Sammlung (Collection) aller Dokumente.
; Schreibe den Namen dieses Dokumentes sowie die Gesamtanzahl aller Dokumente auf die Konsole.
Local $oDoc = _Word_DocGet($oWord, 1)
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocGet Beispiel", _
"Fehler beim Zugriff auf die Sammlung (Collection) von Dokumenten." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocGet Beispiel", "Das erste Dokument in der Sammlung (Collection) wurde ausgewählt." & _
@CRLF & "Name: " & $oDoc.Name & @CRLF & "Gesamtzahl an Dokumenten: " & @extended)