_Word_DocExport

Beschreibung anzeigen in

Exports the document or a range as PDF or XPS

#include <Word.au3>
_Word_DocExport ( $oDoc, $sFileName [, $iFormat = $WdExportFormatPDF [, $iRange = $WdExportAllDocument [, $iFrom = Default [, $iTo = Default [, $bOpenAfterExport = False [, $bIncludeProperties = True [, $iCreateBookmarks = Default [, $bUseISO19005 = False]]]]]]]] )

Parameter

$oDoc	Word Dokument Objekt des zu exportierenden Dokumentes
$sFileName	Pfad/Name der Datei als die das Word Dokument exportiert werden soll
$iFormat	[optional] Für den Export zu verwendendes Format. Kann eine Konstante der WdExportFormat Aufzählung sein. (Standard = $WdExportFormatPDF)
$iRange	[optional] Legt fest, was exportiert werden soll. Kann eine Konstante der WdExportRange Aufzählung sein. (Standard = $WdExportAllDocument)
$iFrom	[optional] Die Seitennummer mit der der Export beginnen soll (Standard = beginne am Anfang des Dokumentes)
$iTo	[optional] Die Seitennummer mit der der Export beendet werden soll (Standard = ende am Ende des Dokumentes)
$bOpenAfterExport	[optional] True zeigt die Exportdatei in inm Viewer an (Standard = False)
$bIncludeProperties	[optional] True gibt an, dass die Dokumenteneigenschaften in der Exportdatei inkludiert sein sollen (Standard = True)
$iCreateBookmarks	[optional] Gibt an, ob Bookmarks und deren Typ mit exportiert werden sollen. Kann eine Konstante der WdExportCreateBookmarks Aufzählung sein (Standard)
$bUseISO19005	[optional] Gibt an, ob der Export als PDF/A (von externen Ressourcen unabhängige PDF) erstellt werden soll (Standard = False)

Rückgabewert

Erfolg:	1.
Fehler:	0 und setzt das @error Flag auf ungleich null.
@error:	1 - $oDoc ist kein Objekt 2 - $sFileName ist leer 3 - Ein Fehler wird vom Export zurückgegeben. @extended wird auf den COM Fehlercode gesetzt

Beispiel

Beispiel 1

#include <MsgBoxConstants.au3>
#include <Word.au3>

; Erzeugt ein neues oder stellt eine Verbindung zu einem bestehenden Word-Objekt her
Local $oWord = _Word_Create()
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocExport Beispiel 1", _
        "Fehler beim Erstellen eines neuen Word-Anwendungsobjektes." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
; Öffnet das Word Testdokument
Local $oDoc = _Word_DocOpen($oWord, @ScriptDir & "\Extras\Test.doc", Default, Default, True)
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocExport Beispiel 1", _
        "Fehler beim Öffnen von '.\Extras\Test.doc'." & @CRLF & "@error = " & @error & ", @extended = " & @extended)

; Exportiert das gesamte Dokument unter Verwendung von standard Parameterwerten
Local $sFileName = @TempDir & "\Test1.pdf"
_Word_DocExport($oDoc, $sFileName)
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocExport Beispiel 1", _
        "Fehler beim Exportieren des Dokumentes." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
ShellExecute($sFileName)
MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocExport Beispiel 1", _
        "Das gesamte Dokument wurde erfolgreich exportiert in Datei: " & $sFileName)

Beispiel 2

#include <MsgBoxConstants.au3>
#include <Word.au3>

; Erzeugt ein neues oder stellt eine Verbindung zu einem bestehenden Word-Objekt her
Local $oWord = _Word_Create()
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocExport Beispiel 2", _
        "Fehler beim Erstellen eines neuen Word-Anwendungsobjektes." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
; Öffnet das Word Testdokument
Local $oDoc = _Word_DocOpen($oWord, @ScriptDir & "\Extras\Test.doc", Default, Default, True)
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocExport Beispiel 2", _
        "Fehler beim Öffnen von '.\Extras\Test.doc'." & @CRLF & "@error = " & @error & ", @extended = " & @extended)

; Exportiert einen Bereich (die Zeilen 2 und 3) als PDF/A und zeigt die erstellte Exportdatei an
Local $oRange = _Word_DocRangeSet($oDoc, -1, $wdParagraph, 1, $wdParagraph, 2)
Local $sFileName = @TempDir & "\Test2.pdf"
_Word_DocExport($oRange, $sFileName, Default, $wdExportFromTo, Default, Default, True, Default, Default, True)
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocExport Beispiel 2", "Fehler beim Exportieren des Dokumentes." & _
        @CRLF & "@error = " & @error & ", @extended = " & @extended)
MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocExport Beispiel 2", _
        "Der angegebene Bereich wurde erfolgreich exportiert nach: " & $sFileName)

Beispiel 3

#include <MsgBoxConstants.au3>
#include <Word.au3>

; Erzeugt ein neues oder stellt eine Verbindung zu einem bestehenden Word-Objekt her
Local $oWord = _Word_Create()
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocExport Beispiel 3", _
        "Fehler beim Erstellen eines neuen Word-Anwendungsobjektes." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
; Öffnet das Testdokument
Local $oDoc = _Word_DocOpen($oWord, @ScriptDir & "\Extras\Test.doc", Default, Default, True)
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocExport Beispiel 3", _
        "Fehler beim Öffnen von '.\Extras\Test.doc'." & @CRLF & "@error = " & @error & ", @extended = " & @extended)

; Exportiert die aktuelle Seite
Local $sFileName = @TempDir & "\Test3.pdf"
_Word_DocExport($oDoc, $sFileName, Default, $wdExportCurrentPage)
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocExport Beispiel 3", _
        "Fehler beim Exportieren des Dokumentes." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocExport Beispiel 3", _
        "Die aktuelle Seite wurde erfolgreich exportiert nach: " & $sFileName)
ShellExecuteWait($sFileName)

Funktionreferenz