_Word_DocPrint
Beschreibung anzeigen in
Druckt das gesamte oder Teile des Dokumentes
#include <Word.au3>
_Word_DocPrint ( $oDoc [, $bBackground = False [, $iCopies = 1 [, $iOrientation = -1 [, $bCollate = True [, $sPrinter = "" [, $iRange = $WdPrintAllDocument [, $vFrom = 0 [, $vTo = 0 [, $sPages = "" [, $iPageType = $WdPrintAllPages [, $iItem = $WdPrintDocumentContent]]]]]]]]]]] )
Parameter
| $oDoc | Word Dokument Objekt |
| $bBackground | [optional] Bei True erfolgt der Ausdruck asynchron während das Skript weiterläuft (Standard = False) |
| $iCopies | [optional] Anzahl der zu druckenden Kopien (Standard = 1) |
| $iOrientation | [optional] Gibt die Seitenorientierung an: -1 - Verwendet die aktuelle Seitenorientierung (Standard) 0 - Hochformat (Portrait) ($WdOrientPortrait Konstante aus der WdOrientation Aufzählung) 1 - Querformat (Landscape) ($WdOrientLandscape Konstante aus der WdOrientation Aufzählung) |
| $bCollate | [optional] Bei True werden zuerst alle Seiten des Dokumentes gedruckt, bevor die nächste Kopie gedruckt wird (Standard = True) |
| $sPrinter | [optional] Definiert den zu verwendenden Drucker (Standard = "" = der aktive Drucker) |
| $iRange | [optional] Gibt den zu druckenden Bereich an. Kann eine der Konstanten aus der WdPrintOutRange Aufzählung sein. (Standard = $WdPrintAllDocument = druckt das gesamte Dokument) |
| $vFrom | [optional] Die erste zu druckende Seite wenn $iRange auf $WdPrintFromTo gesetzt ist |
| $vTo | [optional] Die letzte zu druckende Seite wenn $iRange auf $WdPrintFromTo gesetzt ist |
| $sPages | [optional] Die zu druckenden Seiten bzw. Seitenbereiche, getrennt durch Kommas, wenn $iRange auf 4 gesetzt ist. Zum Beispiel druckt "2, 6-10" die Seite 2 und den Seitenbereich von 6 bis 10 (Standard = "") |
| $iPageType | [optional] Der Seitentyp der gedruckt werden soll. Kann eine der Konstanten aus der WdPrintOutPages Aufzählung sein (gerade, ungerade oder alle Seiten). (Standard = $WdPrintAllPages = druckt alle Seiten) |
| $iItem | [optional] Legt den zu druckenden Teil des Dokuments fest. Kann eine Konstante der WdPrintOutItem Aufzählungen sein (Standard = $WdPrintDocumentContent = Inhalt des Dokuments) |
Rückgabewert
| Erfolg: | 1. |
| Fehler: | 0 and Setzt das @error Flag auf ungleich null. |
| @error: | 1 - $oDoc ist kein Objekt 2 - Die Seitenorientierung konnte nicht gesetzt werden. @extended wird auf den COM Fehlercode gesetzt 3 - Der Drucker konnte nicht definiert werden. @extended wird auf den COM Fehlercode gesetzt 4 - Fehler beim Drucken des Dokumentes. @extended wird auf den COM Fehlercode gesetzt |
Bemerkungen
Wird $bBackground auf True gesetzt, so wird das Skript nur so lange angehalten, bis Word das Dokument an den Drucker gesendet hat.
Wird ein Drucker angegeben, muss auf Groß-/Kleinschreibung von \\servername\printer geachtet werden.
Verwandte Funktionen
Beispiel
#include <MsgBoxConstants.au3>
#include <Word.au3>
; Erzeugt ein neues oder stellt eine Verbindung zu einem bestehenden Word-Objekt her
Local $oWord = _Word_Create()
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocPrint Beispiel", _
"Fehler beim Erstellen des Word-Anwendungsobjektes." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
; Öffnet das Testdokument
Local $oDoc = _Word_DocOpen($oWord, @ScriptDir & "\Extras\Test.doc", Default, Default, True)
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocPrint Beispiel", _
"Fehler beim Öffnen von '.\Extras\Test.doc'." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
; Druckt das gesamte Dokument mit Standardeinstellungen
Local $sActivePrinter = $oDoc.Application.ActivePrinter
MsgBox($MB_SYSTEMMODAL, "", "Der aktive Drucker ist: " & $sActivePrinter)
_Word_DocPrint($oDoc)
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocPrint Beispiel", _
"Fehler beim Drucken des Dokumentes." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocPrint Beispiel", "Das Dokument wurde erfolgreich ausgegeben auf Drucker: " & _
$sActivePrinter)