Funktionreferenz

_Word_DocLinkAdd

Beschreibung anzeigen in

Fügt einen Hyperlink in das Dokument ein

#include <Word.au3>
_Word_DocLinkAdd ( $oDoc [, $oAnchor = Default [, $sAddress = Default [, $sSubAddress = Default [, $sScreenTip = Default [, $sTextToDisplay = Default [, $sTarget = Default]]]]]] )

Parameter

$oDoc Word Document Objekt
$oAnchor [optional] Bereichs-Objekt (Range) des Textes oder Graphikobjektes auf das der Hyperlink gesetzt werden soll
(Standard = Der Link wird auf das ganze Dokument gesetzt)
$sAddress [optional] Die Adresse des Links.
Dies kann eine E-Mailadresse, eine Internet-Adresse oder ein Dateiname sein (Standard = Adresse des aktuellen Dokumentes)
$sSubAddress [optional] Der Name einer Markierung innerhalb der Zieldatei (Lesezeichen (Bookmark), benannter Bereich (Range) oder Name einer Folie) (Standard = Keines)
$sScreenTip [optional] Der Text, der angezeigt werden soll, wenn sich die Maus über dem Hyperlink befindet (Standard = Wert von $sAddress)
$sTextToDisplay [optional] Der Text, der als Hyperlink angezeigt werden soll.
Ersetzt den Text oder das Graphikobjekt das als $oAnchor angegeben wurde (Standard = Wert von $sAddress)
$sTarget [optional] Name des Rahmens (Frame) oder Fensters in dem der angegebene Hyperlink geladen werden soll

Rückgabewert

Erfolg: 1.
Fehler: 0 und setzt das @error Flag auf ungleich null.
@error: 1 - $oDoc ist kein Objekt
2 - Der Link konnte nicht erzeugt werden. @extended wird auf den COM Fehlercode gesetzt
3 - $oAnchor ist kein gültiges Bereichs-Objekt (Range)

Verwandte Funktionen

_Word_DocLinkGet

Beispiel

Beispiel 1

#include <MsgBoxConstants.au3>
#include <Word.au3>

; Erzeugt ein neues oder stellt eine Verbindung zu einem bestehenden Word-Objekt her
Local $oWord = _Word_Create()
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocLinkAdd Beispiel 1", _
        "Fehler beim Erstellen des Word-Anwendungsobjektes." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
; Öffnet das Testdokument im Lesemodus
Local $oDoc = _Word_DocOpen($oWord, @ScriptDir & "\Extras\Test.doc", Default, Default, True)
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocLinkAdd Beispiel 1", _
        "Fehler beim Öffnen von '.\Extras\Test.doc'." & @CRLF & "@error = " & @error & ", @extended = " & @extended)

; macht das vierte Wort des Dokumentes zu einem Link auf die engl. AutoIt Homepage
Local $oRange = _Word_DocRangeSet($oDoc, -1, $wdWord, 3, $wdWord, 1)
_Word_DocLinkAdd($oDoc, $oRange, "http://www.autoitscript.com")
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocLinkAdd Beispiel 1", _
        "Fehler beim Hinzufügen des Links." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocLinkAdd Beispiel 1", "Wort 4 des Dokumentes ist nun ein Link zur engl. AutoIt Homepage.")

Beispiel 2

#include <MsgBoxConstants.au3>
#include <Word.au3>

; Erzeugt ein neues oder stellt eine Verbindung zu einem bestehenden Word-Objekt her
Local $oWord = _Word_Create()
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocLinkAdd Beispiel 2", _
        "Fehler beim Erstellen des Word-Anwendungsobjektes." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
; Öffnet das Testdokument im Lesemodus
Local $oDoc = _Word_DocOpen($oWord, @ScriptDir & "\Extras\Test.doc", Default, Default, True)
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocLinkAdd Beispiel 2", _
        "Fehler beim Öffnen von '.\Extras\Test.doc'." & @CRLF & "@error = " & @error & ", @extended = " & @extended)

; Fügt einen Link am ENde des Dokumentes ein und setzt die Parameter ScreenTip und TextToDisplay
Local $oRange = _Word_DocRangeSet($oDoc, -2) ; Springt zum Ende des Dokumentes
$oRange.Text = " " ; Fügt ein Leerzeichen am Ende des Dokumentes ein
$oRange = _Word_DocRangeSet($oDoc, -2)
_Word_DocLinkAdd($oDoc, $oRange, "http://www.autoitscript.com", Default, "AutoIt homepage", _
        "Hyperlink 3 - Weiterer Link auf die eng. to the AutoIt Homepage")
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocLinkAdd Beispiel 2", _
        "Fehler beim Hinzufügen des Links." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocLinkAdd Beispiel 2", "Hyperlink am Ende des Dokumentes eingefügt.")