Funktionreferenz


_Word_DocLinkGet

Beschreibung anzeigen in

Gibt eine Sammlung (Collection) aller Links des Dokumentes oder einen einzelnen Link zurück

#include <Word.au3>
_Word_DocLinkGet ( $oDoc [, $iIndex = Default] )

Parameter

$oDoc Word Dokument Objekt
$iIndex [optional] Definiert, was zurückgegeben werden soll:
    Default - Gibt eine Sammlung (Collection) aller Links des Dokumentes zurück (Standard)
    n - Die Index-Nummer des Links der zurückgegeben werden soll (der Index beginnt mit 1)

Rückgabewert

Erfolg: Das Objekt einer Sammlung (Collection) oder das Objekt eines einzelnen links.
@extended wird auf die Gesamtzahl aller Links im Dokument gesetzt
Fehler: 0 und setzt das @error Flag auf ungleich null.
@error: 1 - $oDoc ist kein Objekt
2 - $iIndex ist ungültig (muss eine Ganzzahl > 0 und <= Hyperlinks.Count sein) oder das Schlüsselwort Default
3 - Fehler beim Zugriff auf die Liste aller Links. @extended wird auf den COM Fehlercode gesetzt

Verwandte Funktionen

_Word_DocLinkAdd

Beispiel

Beispiel 1

#include <MsgBoxConstants.au3>
#include <Word.au3>

; Erzeugt ein neues oder stellt eine Verbindung zu einem bestehenden Word-Objekt her
Local $oWord = _Word_Create()
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocLinkGet Beispiel 1", _
        "Fehler beim Erstellen des Word-Anwendungsobjektes." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
; Öffnet das Testdokument im Lesemodus
Local $oDoc = _Word_DocOpen($oWord, @ScriptDir & "\Extras\Test.doc", Default, Default, True)
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocLinkGet Beispiel 1", "Fehler beim Öffnen von '.\Extras\Test.doc'. @error = " & _
        @error & ", @extended = " & @extended)

; Gib für jeden Hyperlink des Dokumentes einige Eigenschaften aus
Local $oLinks = _Word_DocLinkGet($oDoc)
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocLinkGet Beispiel 1", _
        "Fehler beim Zugriff auf die Hyperlinks." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
Local $sResult = "Anzahl der Hyperlinks im Dokument: " & @extended & @CRLF & @CRLF
For $oLink In $oLinks
    $sResult = $sResult & "Text: " & $oLink.TextToDisplay & @CRLF & "Adresse: " & $oLink.Address & _
            @CRLF & "------------------------------------------" & @CRLF
Next
MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocLinkGet Beispiel 1 - Liste aller Hyperlinks im Dokument", $sResult)

Beispiel 2

#include <MsgBoxConstants.au3>
#include <Word.au3>

; Erzeugt ein neues oder stellt eine Verbindung zu einem bestehenden Word-Objekt her
Local $oWord = _Word_Create()
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocLinkGet Beispiel 2", _
        "Fehler beim Erstellen des Word-Anwendungsobjektes." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
; Öffnet das Testdokument im Lesemodus
Local $oDoc = _Word_DocOpen($oWord, @ScriptDir & "\Extras\Test.doc", Default, Default, True)
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocLinkGet Beispiel 2", "Fehler beim Öffnen von '.\Extras\Test.doc'. @error = " & _
        @error & ", @extended = " & @extended)

; Gibt einige Eigenschaften des zweiten Hyperlinks aus
Local $oLink = _Word_DocLinkGet($oDoc, 2)
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocLinkGet Beispiel 2", _
        "Fehler beim Zugriff auf die Hyperlinks." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
Local $sResult = "Anzahl der Hyperlinks im Dokument: " & @extended & @CRLF & @CRLF & _
        "Text: " & $oLink.TextToDisplay & @CRLF & _
        "Adresse: " & $oLink.Address & @CRLF & _
        "Screentip: " & $oLink.Screentip
MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocLinkGet Beispiel 2 - Eigenschaften von Hyperlink #2", $sResult)